Realizar hoja de presupuestos.

Una idea sería tener una lista de esos productos del catálogo con su precio y su descuento correspondiente. El cliente va viendo sus características de forma interactiva y si le interesa alguno lo marca y también marca el número de unidades que quiere comprar. Cuando desee finalizar se muestra una lista de todos los productos seleccionados junto con su precio por unidad, precio de todas las unidades, descuento aplicado, total, etc.
No se si esto se ajusta a lo que tu quieres. La idea de hacerlo sería con una lista inicial de productos. La tendrías que definir en un script de película:
Global Producto
Global Compra
Global descuentoTotal
Global numCompras
On prepareMovie me
Producto = []
Producto[1] = [#nombre: "Producto 1", #precio: 150, #descuento: 0]
Producto[2] = [#nombre: "Producto 2", #precio: 50, #descuento: 10]
Producto[3] = [#nombre: "Producto 3", #precio: 200, #descuento: 2]
Producto[4] = [#nombre: "Producto 4", #precio: 70, #descuento: 7]
Producto[5] = [#nombre: "Producto 5", #precio: 96, #descuento: 12]
Compra = [] -- Lista de la compra del cliente
numCompras = 0 -- numero de productos que quiere comprar
descuentoTotal = 1 -- 1% de descuento en toda compra
end
En la ficha de cada producto del catálogo tendrías que preguntar de alguna forma cuántas unidades quiere. Por defecto pones 0. Si lo cambia añades una línea como la siguiente:
numCompras = numCompras + 1
Compra[numCompras] = [#producto: 1, #unidades: 3]
En este ejemplo establezco que el cliente quiere comprar 3 unidades del producto 1.
Cuando el cliente quiera finalizar tendrías que poner el resultado total. Creas un campo de texto llamado Cuenta por ejemplo. Y en el vas añadiendo todo:
Global Compra
Global Producto
Global numCompra
Global descuentoTotal
On mouseUp me
member("Cuenta").text = "TOTAL PRODUCTOS CLIENTE" & RETURN & RETURN & \
"PRODUCTO UNIDADES PRECIO UNIDAD TOTAL" & RETURN & \
"-------- -------- ------------- -----" & RETURN
Total = 0
repeat with n=1 to numCompra
Unidades = Compra[n].unidades
Precio = Producto[ Compra[n].producto*1 ].precio
Descuento = Producto[ Compra[n].producto*1 ].descuento
TotalUnidades = ( (Unidades * Precio) - ((Unidades * Precio * Descuento)/100))
Total = Total + TotalUnidades
member("Cuenta").text = member("Cuenta").text & Producto[ Compra[n].producto ].nombre & " " & \
Unidades & " " & \
Precio & " " & \
TotalUnidades & RETURN
end repeat
member("Cuenta").text = member("Cuenta").text & "-------- -------- ------------- -----" & RETURN & RETURN
member("Cuenta").text = member("Cuenta").text & "TOTAL = " & Total - (Total * descuentoTotal)/100
end
Más o menos sería eso. Repasa los cálculos.
Para imprimir tanto la cuenta como las fichas de productos tienes que usar el xtra PrintOMagic. Descárgatelo de:
http://www.printomatic.com/products.cfm?page=1
Aquí tienes un script para imprimir imágenes y texto:
on mouseUp me
set doc = new(xtra "PrintOMatic")
if not objectP(doc) then
alert( "Error al inicializar." )
else
newPage doc
-- imagen de 200x200 pixels
drawPicture doc, member "imagen", Rect(0,0,200,200)
append doc, member "Cuenta", TRUE
if doJobSetup(doc) then print doc
set doc = 0
end if
end
Dispones de varias funciones que puedes consultar en la web de PrintOMatic:
http://www.printomatic.com/docs/pom_index.htm