Error al conectar visual basic con access2000

Hola según leo estas usando DAO...
Entonces para mostrar un conjunto de registros en un DBGrid, tienes que enlazarlo a un control Data
Las propiedades a establecer en un control Data son:
Connect = Access 2000;
DataBaseName = Ruta y nombre del archivo mdb
RecordSource = El nombre de una tabla o una sentencia sql de consulta
Para enlazar el control DBGrid con el control Data cambia la propiedad DataSource del DBGrid al nombre del control Data.
Yo te recomiendo usar ADO para tus conexiones con base de datos.
'Espero que este sencillo ejemplo te sirva de ayuda....
'
'Crea un proyecto EXE Estándard y añade una referencia a...
'Microsoft ActiveX Data Object 2.6 Library
'Agrega el componente...
'Microsoft Datagrid Control OLEDB
'Agrega los siguientes controles al formulario
'Un Label, un TextBox, un CommandButton y un Datagrid
'Pega todo el siguiente codigo en tu formulario
'Cambia la ruta de la base de datos si es necesario
Const RUTA_DATABASE = "C:\Archivos de programa\Microsoft Visual Studio\VB98\BIBLIO.MDB"
Const TABLA_TITLES = "SELECT * FROM TITLES"
Private Sub Form_Load()
'cambiando propiedades del control Label1
With Label1
.AutoSize = True
.Caption = "Texto a buscar:"
.Move 90, 90
End With
'cambiando propiedades del control Text1
With Text1
.Text = "Ingresa aquí el texto que quieres buscar en el campo TITLES..."
.Move 90, 330, 4800, 315
End With
'cambiando propiedades del control Command1
With Command1
.Caption = "Buscar..."
.Move 5000, 330, 1400, 315
End With
'cambiando propiedades del control Datagrid1
DataGrid1.Move 90, 750, 6400, 3760
Me.Move 0, 0, 6680, 5000
'Listar todos los registro de la tabla Titles
ListarRegistros TABLA_TITLES
End Sub
Private Sub Text1_GotFocus()
'Seleccionar el texto al recibir el enfoque
With Text1
.SelStart = 0
.SelLength = Len(Trim(.Text))
End With
End Sub
Private Sub Command1_Click()
Dim strWhere As String
strWhere = ""
If Len(Trim(Text1.Text)) > 0 Then
strWhere = " WHERE Title LIKE '%" & Text1.Text & "%'"
End If
ListarRegistros TABLA_TITLES & strWhere
End Sub
'Procedimiento para obtener los registro de la tabla TITLES
Private Sub ListarRegistros(ByVal SentenciaSQL As String)
Dim cnConnect As ADODB.Connection
Dim rstTitles As ADODB.Recordset
Set cnConnect = New ADODB.Connection
cnConnect.ConnectionString = "Provider=Microsoft.Jet.Oledb.4.0;" & _
"Data Source=" & RUTA_DATABASE
cnConnect.Open
Set rstTitles = New ADODB.Recordset
With rstTitles
.CursorLocation = adUseClient
.CursorType = adOpenStatic
.LockType = adLockBatchOptimistic
.ActiveConnection = cnConnect
.Open SentenciaSQL
.ActiveConnection = Nothing
End With
Set DataGrid1.DataSource = rstTitles
Set cnConnect = Nothing
End Sub
Saludos
Armando Días