Hacer coincidir dos celdas numéricas

He estado viendo lo que quieres y lo más sencillo es crearte una función y después utilizarla.
Te he preparado esta:
Option Explicit
Function BuscaGanadorPorra(ByVal nGolesLocal As Integer, ByVal nGolesVisitante As Integer, _
                           ByRef rangoResultados As Range, _
                           ByRef rangoNombres As Range)
    Dim i As Integer
    Dim aux As String
    Dim resLoc As Variant
    Dim resVis As Variant
    ' Comprobamos los datos de los parámetros que nos han pasado
    ' Los resultados tienen que estar en una única fila
    If rangoResultados.Rows.Count > 1 Then
        MsgBox "No se puede poner un rango de resultados de más de una fila"
        Error 1
        Exit Function
    End If
    ' Los nombres también
    If rangoNombres.Rows.Count > 1 Then
        MsgBox "No se puede poner un rango de apostantes de más de una fila"
        Error 1
        Exit Function
    End If
    ' Los nombres y los resultados tienen que tener el mismo número de columnas
    If rangoResultados.Columns.Count <> rangoNombres.Columns.Count Then
        MsgBox "Las columnas del rango de resultados y el de apostantes debens ser las mismas"
        Error 1
        Exit Function
    End If
    ' Ya sabemos que los datos son correctos. Empezamos a buscar los que han acertado
aux = "" ' De momento nadie
    For i = 1 To rangoResultados.Columns.Count Step 2
        resLoc = rangoResultados.Cells(1, i)
        resVis = rangoResultados.Cells(1, i + 1)
        If resLoc <> "" And resVis <> "" And IsNumeric(resLoc) And IsNumeric(resVis) Then
            If resLoc = nGolesLocal And resVis = nGolesVisitante Then
                ' Acertante
                If aux <> "" Then aux = aux & " , "
                aux = aux & rangoNombres.Cells(1, i)
            End If
        End If
    Next i
    If aux = "" Then aux = "--" ' No ha acertado nadie
    BuscaGanadorPorra = aux
End Function
Después sólo tienes que poner en la casilla la fórmula para llama a esta función. En la celda K2 pondrías la siguiente fórmula:
=BuscaGanadorPorra(E2;F2;O2:AH2;$O$1:$AH$1)