Para Dante - Ayuda con esta Macro

Hola Dante:

¿

Podrías ayudarme con esta macro?

Lo que pasa es que grave esta macho pero es muy lenta en su ejecución y quisiera hacerla más rápida. Esta es la macro:

Private Sub CommandButton1_Click()

Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Application.EnableEvents = False
ActiveSheet.DisplayPageBreaks = False

Dim Periodo As Integer 'Declaramos la variable
Sheets("LVIVA").Activate 'Activamos la Hoja
Periodo = txtPeriodo.Value 'Asignamos a textbox el valor de la variable
Cells(2, 21) = Periodo 'coordenadas el valor de la variable Periodo dentro de la hoja de excel activa

'Filtramos los datos
Sheets("LVI").Range("A1:S10001").AdvancedFilter Action:=xlFilterCopy, _
CriteriaRange:=Range("LVIVA!LVIVACriterios"), CopyToRange:=Range("A4:S1500" _
), Unique:=False
'Ordenamos los datos primero por numero de documento, fecha y numero de control
Range("A4").Select
Range(Selection, Selection.End(xlToRight)).Select
Range(Selection, Selection.End(xlDown)).Select
ActiveWorkbook.Worksheets("LVIVA").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("LVIVA").Sort.SortFields.Add Key:=Range("E5:E1500"), _
SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
ActiveWorkbook.Worksheets("LVIVA").Sort.SortFields.Add Key:=Range("C5:C1500"), _
SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
ActiveWorkbook.Worksheets("LVIVA").Sort.SortFields.Add Key:=Range("D5:D1500"), _
SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets("LVIVA").Sort
.SetRange Range("A4:S1500")
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
'Númeramos las filas y copiamos el archivo a la hoja LVTXT
Range("B5").Select
ActiveCell.FormulaR1C1 = "1"
Range("B6").Select
ActiveCell.FormulaR1C1 = "=IF(RC[-1]=3,R[-1]C+1,"""")"
Range("B6").Select
Selection.Copy
Range("A6").Select
Selection.End(xlDown).Select
Range("B1500").Select
Range(Selection, Selection.End(xlUp)).Select
ActiveSheet.Paste
Application.CutCopyMode = False
Sheets("LVTXT").Select
Cells.Select
Selection.ClearContents
Sheets("LVIVA").Select
Range("A5").Select
Range(Selection, Selection.End(xlToRight)).Select
Range(Selection, Selection.End(xlDown)).Select
Selection.Copy
Sheets("LVTXT").Select
Range("A1").Select
ActiveSheet.Paste
Application.CutCopyMode = False
Columns("R:S").Select
Range("S1").Activate
Selection.ClearContents
ActiveWorkbook.Save
'Configuramos 17 columnas en el listbox1
ListBox1.ColumnCount = 17
ListBox1.TextAlign = fmTextAlignRight
ListBox1.ColumnHeads = False
ListBox1.ColumnWidths = "25;15;60;40;60;20;60;160;60;60;60;60;60;60;60;60;60"

'Llenamos la lista
ListBox1.RowSource = "LVTXT!A1:Q" & Sheets("LVTXT").Range("A" & Rows.Count).End(xlUp).Row

'Configuramos 8 columnas en el listbox2 PARA LOS TOTALES
ListBox2.ColumnCount = 8
ListBox2.TextAlign = fmTextAlignRight
ListBox2.ColumnHeads = False
ListBox2.ColumnWidths = "60;60;60;60;60;60;60;60"

'Llenamos la lista
ListBox2.RowSource = "LVIVA!Z2:AG" & Sheets("LVIVA").Range("Z" & Rows.Count).End(xlUp).Row


Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
Application.EnableEvents = True
ActiveSheet.DisplayPageBreaks = True
Application.CutCopyMode = False

End Sub

Lo que hace: primero aciva la Hoja LVIVA luego hace un filtro avanzado después ordena los datos filtrados por numero de documento, fecha y numero de control luego en la Columna Nº numero los registro filtrados ( es decir si el filtro arroja 14 filas se numera de 1 a 14).

Gracias por tu ayuda

1 Respuesta

Respuesta
1

¿Dime cuánto tiempo tarda en la ejecución?

Envíame tu archivo con el formulario, me dices cómo se llama el formulario y qué datos debo poner en el formulario antes de ejecutarlo.

Recuerda poner tu nombre en el asunto del correo.

Reviso la forma de optimizarlo y te envío una propuesta.

Saludos. Dante Amor

hab_ra_ham

Ten envio el archivo

https://mega.co.nz/#!YZYXCICb!DQBa-swGiwyvAeVW6naPhbdCP904lI-yLjQXlh12BvY 

tarda como 5 seg.

Los datos se ingresan en la hoja lvt 

para ejecutarlo solo se selecciona el mes y dar click a procesar

Te anexo el código con los cambios, pero creo que lo más significativo es que no guardes el libro cada vez que ejecutas el filtro.

Private Sub CommandButton1_Click()
'Act.Por Dante Amor
    Application.ScreenUpdating = False
    Set h1 = Sheets("LVIVA")
    Set h2 = Sheets("LVI")
    Set h3 = Sheets("LVTXT")
    h3.Cells.ClearContents
    h1.Columns("A:S").ClearContents
    h1.Cells(2, 21) = Val(txtPeriodo.Value)
    u2 = h2.Range("A" & Rows.Count).End(xlUp).Row
    'Filtramos los datos
    h2.Range("A1:S" & u2).AdvancedFilter _
        Action:=xlFilterCopy, _
        CriteriaRange:=Range("LVIVA!LVIVACriterios"), _
        CopyToRange:=h1.Range("A4"), Unique:=False
    'Ordenamos los datos primero por numero de documento, fecha y numero de control
    u1 = h1.Range("A" & Rows.Count).End(xlUp).Row
    If u1 > 4 Then
        With h1.Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("E5:E" & u1)
            .SortFields.Add Key:=Range("C5:C" & u1)
            .SortFields.Add Key:=Range("D5:D" & u1)
            .SetRange h1.Range("A4:S" & u1)
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        'Númeramos las filas y copiamos el archivo a la hoja LVTXT
        If h1.[B5] <> "" Then h1.[B5] = 1
        If h1.[B6] <> "" Then h1.[B6] = 2
        If u1 > 6 Then h1.Range("B5:B6").AutoFill Destination:=h1.Range("B5:B" & u1)
        h1.Range("A5:S" & u1).Copy h3.Range("A1")
    End If
    'Configuramos 17 columnas en el listbox1
    ListBox1.ColumnCount = 17
    ListBox1.TextAlign = fmTextAlignRight
    ListBox1.ColumnHeads = False
    ListBox1.ColumnWidths = "25;15;60;40;60;20;60;160;60;60;60;60;60;60;60;60;60"
    'Llenamos la lista
    ListBox1.RowSource = h3.Name & "!A1:Q" & h3.Range("A" & Rows.Count).End(xlUp).Row
    'Configuramos 8 columnas en el listbox2 PARA LOS TOTALES
    ListBox2.ColumnCount = 8
    ListBox2.TextAlign = fmTextAlignRight
    ListBox2.ColumnHeads = False
    ListBox2.ColumnWidths = "60;60;60;60;60;60;60;60"
    'Llenamos la lista
    ListBox2.RowSource = h1.Name & "!Z2:AG2" '& h1.Range("Z" & Rows.Count).End(xlUp).Row
    Application.ScreenUpdating = True
End Sub

Encontré un detalle a la macro, prueba con esta

Private Sub CommandButton1_Click()
'Act.Por Dante Amor
    Application.ScreenUpdating = False
    Set h1 = Sheets("LVIVA")
    Set h2 = Sheets("LVI")
    Set h3 = Sheets("LVTXT")
    h3.Cells.ClearContents
    h1.Columns("A:S").ClearContents
    h1.Cells(2, 21) = Val(txtPeriodo.Value)
    u2 = h2.Range("A" & Rows.Count).End(xlUp).Row
    'Filtramos los datos
    h2.Range("A1:S" & u2).AdvancedFilter _
        Action:=xlFilterCopy, _
        CriteriaRange:=Range("LVIVA!LVIVACriterios"), _
        CopyToRange:=h1.Range("A4"), Unique:=False
    'Ordenamos los datos primero por numero de documento, fecha y numero de control
    u1 = h1.Range("A" & Rows.Count).End(xlUp).Row
    If u1 > 4 Then
        With h1.Sort
            .SortFields.Clear
            .SortFields.Add Key:=h1.Range("E5:E" & u1)
            .SortFields.Add Key:=h1.Range("C5:C" & u1)
            .SortFields.Add Key:=h1.Range("D5:D" & u1)
            .SetRange h1.Range("A4:S" & u1)
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        'Númeramos las filas y copiamos el archivo a la hoja LVTXT
        If h1.[B5] <> "" Then h1.[B5] = 1
        If h1.[B6] <> "" Then h1.[B6] = 2
        If u1 > 6 Then h1.Range("B5:B6").AutoFill Destination:=h1.Range("B5:B" & u1)
        h1.Range("A5:S" & u1).Copy h3.Range("A1")
    End If
    'Configuramos 17 columnas en el listbox1
    ListBox1.ColumnCount = 17
    ListBox1.TextAlign = fmTextAlignRight
    ListBox1.ColumnHeads = False
    ListBox1.ColumnWidths = "25;15;60;40;60;20;60;160;60;60;60;60;60;60;60;60;60"
    'Llenamos la lista
    ListBox1.RowSource = h3.Name & "!A1:Q" & h3.Range("A" & Rows.Count).End(xlUp).Row
    'Configuramos 8 columnas en el listbox2 PARA LOS TOTALES
    ListBox2.ColumnCount = 8
    ListBox2.TextAlign = fmTextAlignRight
    ListBox2.ColumnHeads = False
    ListBox2.ColumnWidths = "60;60;60;60;60;60;60;60"
    'Llenamos la lista
    ListBox2.RowSource = h1.Name & "!Z2:AG2" '& h1.Range("Z" & Rows.Count).End(xlUp).Row
    Application.ScreenUpdating = True
End Sub

Con esta macro no es necesaria la tercera hoja, la carga en el listbox se hace directamente de la hoja LVIVA, con esto se ahorra la copia, ahora debe ser más rápida.

Private Sub CommandButton1_Click()
'Act.Por Dante Amor
    Application.ScreenUpdating = False
    Set h1 = Sheets("LVIVA")
    Set h2 = Sheets("LVI")
    h1.Columns("A:S").ClearContents
    h1.Cells(2, 21) = Val(txtPeriodo.Value)
    u2 = h2.Range("A" & Rows.Count).End(xlUp).Row
    'Filtramos los datos
    h2.Range("A1:S" & u2).AdvancedFilter Action:=xlFilterCopy, _
        CriteriaRange:=h1.Range("LVIVACriterios"), CopyToRange:=h1.Range("A4"), Unique:=False
    'Configuramos 17 columnas en el listbox1
    ListBox1.ColumnCount = 17
    ListBox1.TextAlign = fmTextAlignRight
    ListBox1.ColumnHeads = False
    ListBox1.ColumnWidths = "25;15;60;40;60;20;60;160;60;60;60;60;60;60;60;60;60"
    ListBox1 = ""
    'Configuramos 8 columnas en el listbox2 PARA LOS TOTALES
    ListBox2.ColumnCount = 8
    ListBox2.TextAlign = fmTextAlignRight
    ListBox2.ColumnHeads = False
    ListBox2.ColumnWidths = "60;60;60;60;60;60;60;60"
    ListBox2 = ""
    'Ordenamos los datos primero por numero de documento, fecha y numero de control
    u1 = h1.Range("A" & Rows.Count).End(xlUp).Row
    If u1 > 4 Then
        With h1.Sort
            .SortFields.Clear
            .SortFields.Add Key:=h1.Range("E5:E" & u1)
            .SortFields.Add Key:=h1.Range("C5:C" & u1)
            .SortFields.Add Key:=h1.Range("D5:D" & u1)
            .SetRange h1.Range("A4:S" & u1)
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        'Númeramos las filas y copiamos el archivo a la hoja LVTXT
        If h1.[B5] <> "" Then h1.[B5] = 1
        If h1.[B6] <> "" Then h1.[B6] = 2
        If u1 > 6 Then h1.Range("B5:B6").AutoFill Destination:=h1.Range("B5:B" & u1)
        'Llenamos la lista
        ListBox1.RowSource = h1.Name & "!A5:Q" & u1
        'Llenamos la lista
        ListBox2.RowSource = h1.Name & "!Z2:AG2"
    End If
    Application.ScreenUpdating = True
End Sub

¡Gracias! 

wauuuuu

EXCELENTE!!!!!!!!!!!!!!!!!!!

Muchas gracias funciona de maravilla

Duda 1

En el segundo código que me enviaste en esta línea

'Llenamos la lista
    ListBox2.RowSource = h1.Name & "!Z2:AG2" '& h1.Range("Z" & Rows.Count).End(xlUp).Row
    Application.ScreenUpdating = True
End Sub

hay un apostrofe  ('&...) esto comvirte al codigo en un comentario. Asi l hiciste?? o lo corrijo quitando el apostrofe.

Duda 2

despues de copiar los datos filtrados a la hoja LVTXT necesito borrar las ultimas dos columnas (columnas r y s) ¿Cómo lo hago?

Gracias

Para la duda 1, no quites el apóstrofe.

Para la duda 2, h3.Columns("R:S"). Clearcontents, puedes poner la línea antes de esta línea ListBox1. RowSource

¡Gracias!

Que puedo decir siempre me dejas sin palabras.

El código es perfecto

Gracias

Hola Dante,

El código que me enviaste funciona muy bien pero no vi un pequeño detalle. La siguiente línea de código debería de numerar los registros existentes en la hoja LVIVA. Esta numeración debería de aparecer en la columna b de dicha hoja pero no se esta numerando.

'Númeramos las filas y copiamos el archivo a la hoja LVTXT
        If h1.[B5] <> "" Then h1.[B5] = 1
        If h1.[B6] <> "" Then h1.[B6] = 2
        If u1 > 6 Then h1.Range("B5:B6").AutoFill Destination:=h1.Range("B5:B" & u1)
        h1.Range("A5:S" & u1).Copy h3.¿Range("A1")

Podrías ayudarme?

Gracias

¿Y cuántas filas hay?

Puedes enviarme tu archivo para saber con cuál macro estás trabajando

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas

Al seleccionar celda extraer sus dígitos automáticamente

Necesito dos favores, la idea es que al seleccionar una celda numérica de 4 dígitos del rango "af1;aj42" esta automáticamente extraiga sus cifras a la columna "a1, b1, c1, d1" como se muestra en la imagen Y lo segundo como puedo quitarle el msgbox a...
2 respuestas

Se puede agregar voz a Excel

Tengo una pantalla de vuelo de vuelo donde anotó despegues y arribos, Quiero que cada vez que se produzca un despegue y se agregue hora o aterrice alguno y se ponga la hora, excel diga o se escuche atención Aterrizaje o Atención despegue.
3 respuestas

Gráfico Comparativo por Semanas, en Power Bi.

Espero se encuentren muy bien. Tengo una tabla en Power BI con fechas, códigos, costos y cantidades. La necesidad que tengo es de crear un gráfico o tabla donde pueda comparar y analizar el comportamiento de los costos y las cantidades de un código...
1 respuesta

En una lista para pedidos tengo varios formularios

En una lista para pedidos con varios formularios la vengo usando desde hace tiempo sin ningún problema pero hace días la abrí para hacer un pedido y al pisar en el cuadro donde apunta la flecha para que me abra un otro cuadro donde coloco ciertos...
2 respuestas

Código VBA para crear un botón y guardar en PDF

Tengo un archivo word con 7 capturas, una en cada página (1-7), cual seria el código para crear un botón en la barra de herramientas de acceso rápido para convertir en PDF cada página. El resultado seria 7 pdf.
2 respuestas

Detectar si he marcado Celda dentro de un Rango de Excel.

Tengo un Rango en Hoja Excel: RgoDatos >> $B$3:$V$39 Quiero detectar si la celda que selecciono está dentro de ese Rango Si no está que por omisión me marque B3.
1 respuesta

Dato fecha ya existe en tabla

Como están estimados maestros. En formulario, tengo botón archivar. Envío información a hoja "existencias" a tabla "tbl_existencias". En columna A un Código desde textbox1 En columna B fecha desde textbox "txtFecha2" En columna C total desde textbox2...
2 respuestas

Enviar hoja activa al monitor secundario con vba

He creado una segunda ventana de mi hoja excel con NewWindow, y lo que pretendo es mediante código VBA enviarla al monitor secundario, lo he intentado con Application.SendKeys "^({ESC}+{RIGHT})", pero no lo consigo, con "^{ESC}" estoy tratando de...
2 respuestas

Ingresar información en una hoja y rescatar los datos principales en otra hoja ordenadamente.

Debo hacer cotizaciones y necesito guardar la información de los datos de las personas en una BD, sin ocupar Tablas. Lo principal de esto es que queden ordenada según el número de la cotización y mantener el número correlativo de la cantidad de...
1 respuesta

Como habilitar la Pestaña Automatización en Excel de Office 2021

Quisiera saber cual es el procedimiento para habilitar la pestaña Automatización en Excel 2021 o donde poder bajar ese complemento.
1 respuesta