¿Cómo hago para generar un texto en una celda a partir de un texto específico en otra celda?

.16.01.17

Hola, Marco

La cuestión es si en cada celda tenés sólo esa palabra o es parte de un texto más amplio.

La solución más simple es un condicional del tipo:

=SI(B1="HOY";"ACTUAL";SI(B1="AYER";"PASADO";SI(B1="MAÑANA";"FUTURO";"---")))

[Considerá si usás comas o punto y coma para separar argumentos de las funciones. Yo usé ";"]

Esto si tenés sólo esa palabra en cada celda y así podrías seguir, hasta siete opciones.

Pero si son muchas opciones, conviene armar una tablita de relación del tipo

Luego puedes usar la función BUSCARV, como la que puse en B7. Esta función no tiene límite de casos como la anterior y es más simple de armar.

En caso de que necesités que avise que no encontró resultado se puede combinar con un condicional como en esta alternativa:

=SI(ESNOD(BUSCARV(C7;$A$2:$B$6;2;0));"Nostá"; BUSCARV(C7;$A$2:$B$6;2;0))

Comentame si es lo que buscabas -y, en tal caso, te agradeceré que califiques mi contribución- o escribime de nuevo aquí, si necesitás más apoyo con esto.

Un abrazo

Fernando

(Buenos Aires, Argentina)

.

Hola Fer! gracias por la pronta respuesta... el tema es tiene que buscar en la celda una palabra (la empresa) dentro de un texto, te hago el ej real, la columna B contiene los nombres de todos los usuarios separado con un "/ " a que empresa trabaja (Marisol Flores / Exxo.com), entonces mi objetivo es colocar en la columna A sólo el nombre de la empresa a secas sin el .com por ej Exxo

Eso se puede? porque cuando hice la fórmula de arriba me tiró el siguiente error

Error No se ha encontrado el valor "Marisol Flores / Exxo.com" en la evaluación de VLOOKUP.

y lo armé así como figura en la imagen:

.

Buenas, Marco

OK, era mejor poner el ejemplo real que el que habías mencionado al principio.

En todo caso la solución también pasará por un BUSCARV

Sólo que habrá que aislar el nombre de la compañía, tomándolo a partir del separador (/) para que haga la búsqueda en la tabla auxiliar que tengas.

La fórmula que hace tal cosa es la siguiente:

=BUSCARV(ESPACIOS(DERECHA(B11;LARGO(B11)-ENCONTRAR("/";B11)-1));$D$2:$H$100;2;0)

Primero anidé la función que separa el nombre de la empresa del de la persona y con ese resultado hace la búsqueda.

Si hubiera la posibilidad de que un nombre de empresa no exista en la tabla, la siguiente fórmula lo avisará:

=SI(ESNOD(BUSCARV(ESPACIOS(DERECHA(B11;LARGO(B11)-ENCONTRAR("/";B11)-1));$D$2:$H$100;2;0));"Cia Inex";BUSCARV(ESPACIOS(DERECHA(B11;LARGO(B11)-ENCONTRAR("/";B11)-1));$D$2:$H$100;2;0))

Esta debería ser tu fórmula final.

Una solución alternativa, más pedestre, hubiera sido usar la función Datos-Textos en columnas, con la opción Delimitado (con /) y luego un buscar ".com" y remplazar por "".

Pero la fórmula es preferible

Probala y después decime si te anduvo.

Abrazo!

Fer

.

Puedes hacerlo anidando Sies: si(b1="HOY";"ACTUAL";si(b1="AYER";"PASADO";si(b1=".......)))  , pero si las condiciones pasan de 3, yo prefiero usar buscarv(  de esta manera

=SI(B1="";"";BUSCARV(B1;D1:E6;2;0))

Sólo tendrías que ajustar D1:E6 a las dimensiones reales de tu tabla. Puedes ponerla en una parte de la hoja que no se vea o en otra hoja distinta.

Un saludo