Como comparar palabras y valores de una columna?

Te anexo una macro.

El resultado quedará de la siguiente manera

En la columna H quedará un consecutivo de los valores que coinciden y en la columna I el valor coincidente.

Pero también, en la columna G quedará el consecutivo donde fueron concretadas las coincidencias.

Esta es la macro

Sub Concretadas()
'Por Dante Amor
    col1 = "E"          'columna VENTA / COMPRA
    col2 = "F"          'columna valor
    col3 = "H"          'columna concretada
    col4 = "I"          'columna valores concretados
    col5 = "G"          'columna consecutivo
    n = 1
    '
    For i = 1 To Range(col1 & Rows.Count).End(xlUp).Row
        If Cells(i, col1).Value = "VENTA" Then
            valor = Cells(i, col2).Value
            Set r = Columns(col2)
            Set b = r.Find(valor, LookAt:=xlWhole)
            If Not b Is Nothing Then
                celda = b.Address
                Do
                    'detalle
                    If Cells(b.Row, col2).Value = valor And _
                       Cells(b.Row, col1).Value = "COMPRA" Then
                        u2 = Range(col3 & Rows.Count).End(xlUp).Row + 1
                        Cells(u2, col3).Value = n
                        Cells(u2, col4).Value = valor
                        Cells(i, col5).Value = n
                        Cells(b.Row, col5).Value = n
                        n = n + 1
                        Exit Do
                    End If
                    Set b = r.FindNext(b)
                Loop While Not b Is Nothing And b.Address <> celda
            End If
        End If
    Next
    MsgBox "Fin"
End Sub

Sigue las Instrucciones para un botón y ejecutar la macro

1. Abre tu libro de Excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. En el menú elige Insertar / Módulo
4. En el panel del lado derecho copia la macro
5. Ahora para crear un botón, puedes hacer lo siguiente:
6. Inserta una imagen en tu libro, elige del menú Insertar / Imagen / Autoformas
7. Elige una imagen y con el Mouse, dentro de tu hoja, presiona click y arrastra el Mouse para hacer grande la imagen.
8. Una vez que insertaste la imagen en tu hoja, dale click derecho dentro de la imagen y selecciona: Tamaño y Propiedades. En la ventana que se abre selecciona la pestaña: Propiedades. Desmarca la opción “Imprimir Objeto”. Presiona “Cerrar”
9. Vuelve a presionar click derecho dentro de la imagen y ahora selecciona: Asignar macro. Selecciona: Concretadas
10. Aceptar.
11. Para ejecutarla dale click a la imagen.

.

.