Necesito una Macro que Busque un valor, lo copie y lo pegue en otra hoja
Necesito de sus valiosos conocimientos para programar una Macro que busque un Valor en una Columna y si lo encuentra que copie toda la fila donde se encuentra el valor y lo pegue en otra hoja "Llamada histórico. Ademas que vaya pegando las filas una debajo de la otra que no las reemplace.
1 respuesta
Respuesta de Dante Amor
1
Te anexo la macro
Cambia en la macro en estas líneas por tus datos
Set h1 = Sheets("Hoja1") 'hoja origen
Set h2 = Sheets("Hoja2") 'hoja destino
col = "C" 'columna con valores a buscar
fila = 1 'fila de encabezados
valor = "algo" 'valor a buscarLa macro:
Sub Macro1()
'Por Dante Amor
Application.ScreenUpdating = False
Set h1 = Sheets("Hoja1") 'hoja origen
Set h2 = Sheets("Hoja2") 'hoja destino
col = "C" 'columna con valores a buscar
fila = 1 'fila de encabezados
valor = "algo" 'valor a buscar
'
cn = Columns(col).Column
If h1.AutoFilterMode Then h1.AutoFilterMode = False
u1 = h1.Range(col & Rows.Count).End(xlUp).Row
h1.Range("A" & fila & ":" & col & u1).AutoFilter Field:=cn, Criteria1:=valor
u1 = h1.Range(col & Rows.Count).End(xlUp).Row
If u1 > fila Then
h1.Rows(fila + 1 & ":" & u1).Copy
u2 = h2.Range(col & Rows.Count).End(xlUp).Row + 1
h2.Range("A" & u2).PasteSpecial xlValues
Application.CutCopyMode = False
MsgBox "Datos copiados"
Else
MsgBox "no existen datos a copiar"
End If
If h1.AutoFilterMode Then h1.AutoFilterMode = False
End Sub
Comentario borrado por el autor - Alex Millardo
Dante Amor Saludos, Dante. Esta macro me parece excelente. Necesito un macro parecido, ¿pero qué busque más de un valor en las filas.Se te haría posible subir una modificación que incluya esto? Muchas Gracias de ante mano. - Alex Millardo