¿Cómo se puede enviar por correo información de varias filas dada una condición y que esta se muestre en el cuerpo del mismo?.
Tengo una tabla con información la cual hace referencia a recordatorios, cuando están próximos a vencer, tienen un columna que hace referencia al status el cual aparece como "RENEW" para renovar las fechas, ocuparía que todos las filas que tienen ese estatus fueran ingresadas al cuerpo del correo y que este enviara a un destinatario predeterminado... ¿alguna idea?
1 Respuesta
Puedes filtrar las filas que muestran "RENEW", copiarlas y pegarlas en otra, después envías la información de la otra hoja.
Revisa la siguiente respuesta para enviar un rango de celdas
Enviar correos copiando los rangos de celda
[ sal u dos
Trate de hacerlo, pero cuando estoy grabando la macro para que filtre, al momento de iniciarla nuevamente me aparece un error. Sera que te puedo compartir mi archivo para que le des un vistazo?
gracias de antemano por su ayuda.
Deja por un momento el filtro.
Realiza el filtro manualmente y pon la información en la otra hoja.
Ejecuta la macro para enviar el rango de la otra hoja por correo.
Buen Día,
Ya lo intente, pero no me hace el copiado en el cuerpo del correo, este es el código que adapte a mi planilla
Sub ENVIARCORREO()
Set h = Worksheets("Input")
For i = 8 To h.Range("C" & Rows.Count).End(xlUp).Row
If h.Cells(i, "I") = "RENEW" Then
Set dam = CreateObject("outlook.application").CreateItem(0)
dam.To = h.Cells(i, "L")
dam.Subject = h.Cells(i, "M")
filtrar 'filtra para condicion RENEW
dam.Body = "Alerta: " & h.Cells(i, "D") & ". Acción: " & h.Cells(i, "M")
Range("D45:I51").Copy
'dam.send - todavia no habilitar
dam.Display
End If
Next
MsgBox "Correos enviados"
End Sub
Pero este es el código que tienes que utilizar
Sub Mail_Selection_Range_Outlook_Body()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Set rng = Nothing
On Error Resume Next
'Only the visible cells in the selection
'Set rng = Selection.SpecialCells(xlCellTypeVisible)
'You can also use a fixed range if you want
Set rng = Sheets("Hoja4").Range("A1:F8") '.SpecialCells(xlCellTypeVisible)
On Error GoTo 0
If rng Is Nothing Then
MsgBox "The selection is not a range or the sheet is protected" & _
vbNewLine & "please correct and try again.", vbOKOnly
Exit Sub
End If
With Application
.EnableEvents = False
.ScreenUpdating = False
End With
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
On Error Resume Next
With OutMail
.To = "damor"
.CC = ""
.BCC = ""
.Subject = "tst rango en html"
.HTMLBody = RangetoHTML(rng)
.Display
End With
On Error GoTo 0
With Application
.EnableEvents = True
.ScreenUpdating = True
End With
Set OutMail = Nothing
Set OutApp = Nothing
End Sub
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")
'Close TempWB
TempWB.Close savechanges:=False
'Delete the htm file we used in this function
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function
