Tengo 18 hojas de excel y quiero unirlas en una sola hoja, todas tienen las mismas columnas pero diferentes filas, cómo hago?

Te anexo una macro para unir las hojas en la hoja "Resumen".

La macro supone que tus hojas tienen un encabezado en la fila 1, que tus datos empiezan en la fila 2 y que también empiezan en la columna "A".

Cambia en estas líneas de la macro, por tus datos:

    Set h1 = Sheets("Resumen")      'nombre de la hoja resumen
    j = 2                           'fila inicial de datos
    col = "A"                       'columna inicial de datos

Pon la macro en un módulo:

Sub Resumen()
'Por.Dante Amor
    'Enviar los datos de todas las hojas a la hoja "Resumen"
    '
    Application.ScreenUpdating = False
    Set h1 = Sheets("Resumen")      'nombre de la hoja resumen
    j = 2                           'fila inicial de datos
    col = "A"                       'columna inicial de datos
    h1.Rows(j & ":" & Rows.Count).ClearContents
    For Each h2 In Sheets
        Select Case LCase(h2.Name)
            Case LCase("Resumen")
            Case Else
                u1 = h1.Range(col & Rows.Count).End(xlUp).Row + 1
                u2 = h2.Range(col & Rows.Count).End(xlUp).Row
                h2.Rows(j & ":" & u2).Copy
                h1.Range(col & u1).PasteSpecial xlValues
        End Select
    Next
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
    h1.Select
    Range("A1").Select
    MsgBox "Hojas unidas en la hoja Resumen", vbInformation
End Sub

Sigue las Instrucciones para un botón y ejecutar la macro

1. Abre tu libro de Excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. En el menú elige Insertar / Módulo
4. En el panel del lado derecho copia la macro
5. Ahora para crear un botón, puedes hacer lo siguiente:
6. Inserta una imagen en tu libro, elige del menú Insertar / Imagen / Autoformas
7. Elige una imagen y con el Mouse, dentro de tu hoja, presiona click y arrastra el Mouse para hacer grande la imagen.
8. Una vez que insertaste la imagen en tu hoja, dale click derecho dentro de la imagen y selecciona: Tamaño y Propiedades. En la ventana que se abre selecciona la pestaña: Propiedades. Desmarca la opción “Imprimir Objeto”. Presiona “Cerrar”
9. Vuelve a presionar click derecho dentro de la imagen y ahora selecciona: Asignar macro. Selecciona: Resumen
10. Aceptar.
11. Para ejecutarla dale click a la imagen.

'.[Sal u dos. Dante Amor. No olvides valorar la respuesta. 
'.[Avísame cualquier duda