Quisiera saber como se hace una barra de progreso mientras se ejecuta una macro

Te dejo una posibilidad...

Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Sub DemoProgress()
' Progress Application Statusbar
'
    Dim intIndex As Integer
    Dim sngPercent As Single
    Dim intMax As Integer
    intMax = 100
    For intIndex = 1 To intMax
        sngPercent = intIndex / intMax
        ProgressStyle sngPercent
        DoEvents
        '------------------------
        ' Your code would go here
        '------------------------
        Sleep 100
    Next
    Application.StatusBar = False
End Sub
Public Sub ProgressStyle(Percent As Single)
' Application Status bar
' Pulsing
'
    Dim strTemp As String
    Dim intIndex As Integer
    Dim intLen As Integer
    intLen = 21
    intIndex = Int((Percent * 100) Mod intLen)
    strTemp = String(intLen, "°")
    If intIndex > 0 Then
        Mid(strTemp, intIndex, 1) = "*"
    End If
    Application.StatusBar = "Processing " & strTemp
End Sub

Probablemente tengas que ajustar algo de acuerdo a tu código. Te recomiendo que primero lo pruebes en un archivo 'en blanco' para que veas que hace...

Salu2