Como Imprimir y exrportar PDF hojas con macros seleccionando desde un combobox

Te hice la macro. Para que funcione, es necesario que al seleccionar la hoja del combobox, se active dicha hoja, ya que no se como está hecho tu combobox, hice el código basado en la hoja activa (ActiveSheet) así que asegúrate de que se active la hoja al seleccionarla en el combobox.

El código para imprimir es este:

Sub Imprimir()
ActiveSheet.PrintOut
End Sub

y el código para exportar PDF es este:

Sub ExportarPDF()
Dim Hoja As Worksheet
Dim Libro As Workbook
Dim strName As String
Dim strPath As String
Dim strFile As String
Dim strPathFile As String
Dim myFile As Variant
On Error GoTo errHandler
Set Libro = ActiveWorkbook
Set Hoja = ActiveSheet
strPath = Libro.Path
If strPath = "" Then
  strPath = Application.DefaultFilePath
End If
strPath = strPath & "\"
strName = Replace(Hoja.Name, " ", "")
strName = Replace(strName, ".", "_")
strFile = strName & ".pdf"
strPathFile = strPath & strFile
myFile = Application.GetSaveAsFilename _
    (InitialFileName:=strPathFile, _
        FileFilter:="PDF Files (*.pdf), *.pdf", _
        Title:="Seleccione una carpeta y un nombre para Guardar")
If myFile <> "False" Then
    Hoja.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=myFile, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False
    MsgBox "El archivo PDF ha sido creado y se encuentra en: " & vbCrLf & myFile, vbInformation, "Acción completada..."
End If
Exit Sub
errHandler:
    MsgBox "Ha ocurrido un error." & vbCr & "Numero: " & Err.Number & vbCr & "Descripcion: " & Err.Description, vbCritical, "Error al crear PDF..."
End Sub

Andy