Macro que imprima en PDF 7 áreas de una hoja en Excel

La primera celda que contenga "E1", cuando halle dicha celda, tome la fila de dicha celda como la inicial del área de impresión

Entiendo que en alguna celda de la columna A vas a tener el texto "E1", ¿pero en dónde vas a tener el número de fila?

Puedes poner una imagen para ver los datos que tienes en la columna A (E1, T1, E2, T2, etc) y su correspondiente número de fila. Con una imagen es suficiente.

Pero recuerda que es que los números de fila pueden cambiar, algún día tal vez me toque ingresar una fila adicional entonces ese marcador ya sea T1 o E2 o cualquier otro va a cambiar de fila por eso es que puse los marcadores.

Osea lo que yo imaginaria que haría la macro es encontrar E1 por ejemplo y cuando lo encuentre ... pues esa fila en donde lo encontró es la fila inicial y cuando encuentre T1 esa es la fila final. Haz de cuenta que Los E son donde empiezan las áreas de impresión y las T donde terminan las áreas de impresión pero toca así por que es que en cualquier momento me toca insertar una fila y por eso se desplazan los marcadores a una fila más o viceversa si elimino una fila. Para mi los E y los T simplemente actúan de marcadores de inicio y fin de áreas de impresión.

Prueba la siguiente:

Sub Macro3()
  Dim ar1 As Variant, ar2 As Variant, f As Range, sh As Worksheet
  Dim i As Long, ini As Long, fin As Long, sNom As String, n As Long
  '
  Set sh = Sheets("Resumen del dia")
  ar1 = Array("E1", "T1", "E2", "T2", "E3", "T3", "E4", "T4", _
              "E5", "T5", "E6", "T6", "E7", "T7")
  ar2 = Array("B", "BG", "B", "BF", "B", "BF", "B", "BF", _
              "E", "BH", "B", "BG", "E", "BH")
  '
  For i = 0 To UBound(ar1) Step 2
    Set f = sh.Range("A:A").Find(ar1(i), , xlValues, xlWhole)
    If Not f Is Nothing Then
      ini = f.Row
      Set f = sh.Range("A:A").Find(ar1(i + 1), , xlValues, xlWhole)
      If Not f Is Nothing Then
        fin = f.Row
        n = n + 1
        sh.PageSetup.PrintArea = ar2(i) & ini & ":" & ar2(i + 1) & fin
        sNom = Format(Date, "dd") & " de " & Format(Date, "mmmm") & _
                      " de " & Format(Date, "yyyy") & " hoja " & n
        sh.ExportAsFixedFormat xlTypePDF, _
          ThisWorkbook.Path & "\" & sNom & ".pdf", _
          xlQualityStandard, True, False, , , False
      End If
    End If
  Next
End Sub

Ya puse la macro y la ejecuté pero no hace nada, ni saca error.

Me funciono excelente, lo que pasa es que tenia escondida esa columna A para que no se viera e hice la prueba y no hacia nada, pero me dio por probar nuevamente la macro con la columna A visible y me funciona tal cual como lo quería. No que que posibilidad halla que me le pudieras agregar al comienzo de la macro la opción de hacer visible la columna A y al final de la macro volverla a hacer invisible y de esa manera funcionaria excelente
Gracias