Macro para listar los días de un mes y buscar en otra hoja
Amigos es un gusto saludarlos y a su vez solicitar un apoyo ya que no se como realizar una macro que me permita listar los días de la semana y busque cuantas veces se repite en una lista de una hoja, dejo un ejemplo para ver si alguien me puede ayudar.
Lo que necesito es que si selecciono en D1 el mes de Abril, desde E1 en adelante se coloquen los 30 días de ese mes y si selecciono marzo de igual manera desde E1 se coloquen los 31 días de ese mes. Luego en las filas A y B están varias fechas registradas, en D2 Y D3 estoy colocando los nombres de encabezado de las filas A y B, lo que se quiere para esta parte es que busque cuantas veces se tiene registra la fecha 01/04/2020 dentro de la columna A y luego dentro de la columna B y que ponga la cantidad de veces que se encontró.
Pon la siguiente macro en los eventos de tu hoja
Private Sub Worksheet_Change(ByVal Target As Range)
Dim d As Date
Dim dia As Long
'
If Not Intersect(Target, Range("D1")) Is Nothing Then
If Target.CountLarge > 1 Then Exit Sub
Application.ScreenUpdating = False
Range("E1:AI3").ClearContents
'
d = CDate("01/" & LCase(Target.Value) & "/" & Year(Date))
dia = Day(DateSerial(Year(d), Month(d) + 1, 1) - 1)
Range("E1").Value = 1
Range("E1").AutoFill Range("E1", Cells(1, 5 + dia - 1)), xlFillSeries
'
With Range("E2", Cells(2, 5 + dia - 1))
.FormulaR1C1 = "=COUNTIF(C1,DATEVALUE(R1C&""/""&R1C4&YEAR(TODAY())))"
.Value = .Value
End With
'
With Range("E3", Cells(3, 5 + dia - 1))
.FormulaR1C1 = "=COUNTIF(C2,DATEVALUE(R1C&""/""&R1C4&YEAR(TODAY())))"
.Value = .Value
End With
'
Application.ScreenUpdating = True
End If
End SubSigue las Instrucciones para poner la macro en los eventos de worksheet
- Abre tu libro de excel
- Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
- Del lado izquierdo dice: VBAProject, abajo dale doble click a worksheet(tu hoja)
- En el panel del lado derecho copia la macro
¡Gracias! excelente funciona perfecto una ultima consulta si deseo que el conteo sea no solo ingresando el mes sino también el año ya que ahora me pasaron una lista que incluye fechas de otros años como podría agregar esa validación
