Exportar en la carpeta creada, no funciona

Tengo esto y funciona perfecto. Lo único es que cuando crea la carpeta no exporta en ella sino afuera en la otra que la contiene..

Sub GUARDAR()
'On Error Resume Next
'Abre word
  Dim num As Variant
  Dim base2 As String
  Dim Namek As String
  Dim Carpeta As Object
  Dim ruta As String
  Dim ruta3 As String
  Dim ruta4 As Variant
  Dim carpetafinal As String
   'Ambiente
  Application.ScreenUpdating = False
  Application.DisplayAlerts = False
    '
  num = Sheets("Ficha").Range("F2").Value
  ruta = Environ("USERPROFILE") & "\Dropbox\TODAS\"
  'datos para la carpeta
       base2 = Cells(4, "F") & " " & Cells(4, "G") & " " & Cells(4, "C") & " " & Cells(4, "D") & "-" & num
    'ruta completa
  ruta3 = ruta & base2
  ruta4 = Dir(ruta & "*" & num, vbDirectory)
  carpetafinal = ruta & ruta4
'Folder crear o encontrar
    Application.ScreenUpdating = False
    Set Carpeta = CreateObject("Scripting.FileSystemObject")
         '
  'nombre del archivo
  Namek = num & ("-") & Format(Now, "ddmmyyyy")
If ruta4 <> "" Then
      MsgBox "ENCONTRADO.", vbInformation, "Kutools for Excel"
  'Exportar archivo
      Sheets("PDF").ExportAsFixedFormat xlTypePDF, carpetafinal & "\" & Namek & ".pdf", xlQualityStandard, True, False, , , False
      Else
       Carpeta.CreateFolder (ruta3)
        MsgBox "CREADA.", vbInformation, "Kutools for Excel"
       Sheets("PDF").ExportAsFixedFormat xlTypePDF, carpetafinal & "\" & Namek & ".pdf", xlQualityStandard, True, False, , , False
        End If
Sheets("Ficha").Select
    End Sub

1 Respuesta

Respuesta
1

Está creando la carpeta ruta3

Carpeta. CreateFolder (ruta3)

Pero quieres exportar en la capeta ruta4

Sheets("PDF"). ExportAsFixedFormat xlTypePDF, ruta4

En mi código utilizo la función dir( ) para revisar si existe la carpeta.

arch = Dir(carpetaInicial & "*" & num, vbDirectory)

En tu código, la variable ruta4 no es necesaria, porque estás utilizando esto para revisar si existe la carpeta:

  Set Carpeta = CreateObject("Scripting.FileSystemObject")
  If Carpeta.FolderExists(ruta3) Then

Lo siguiente debería funcionar para lo que necesitas:

Sub GUARDAR()
  Dim num As Variant
  Dim Carpeta As Object
  Dim base2 As String, Namek As String
  Dim ruta As String, ruta3 As String
  'Ambiente
  Application.ScreenUpdating = False
  Application.DisplayAlerts = False
  '
  ruta = Environ("USERPROFILE") & "\Dropbox\TODAS\"
  num = Sheets("Ficha").Range("F2").Value
  'datos para la carpeta
  base2 = Cells(4, "F") & " " & Cells(4, "G") & " " & Cells(4, "C") & " " & Cells(4, "D") & "-" & num
  ruta3 = ruta & base2
  'Folder crear o encontrar
  Set Carpeta = CreateObject("Scripting.FileSystemObject")
  If Carpeta.FolderExists(ruta3) Then
    MsgBox "ENCONTRADO.", vbInformation, "Kutools for Excel"
  Else
    Carpeta.CreateFolder (ruta3)
    MsgBox "CREADA.", vbInformation, "Kutools for Excel"
  End If
  'nombre del archivo
  Namek = num & ("-") & Format(Now, "ddmmyyyy")
  'Exportar archivo
  Sheets("PDF").ExportAsFixedFormat xlTypePDF, ruta3 & "\" & Namek & ".pdf", xlQualityStandard, True, False, , , False
  Sheets("Ficha").Select
End Sub

[Prueba y comentas. 

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas

¿Cómo resolver num a letras en excel?

En un libro excel habilitado para macros al convertir números a letras, en lugar de aparecer el resultado esperado aparece el mensaje # ¿NOMBRE?.
1 respuesta

´No sé que fórmulas usar para resolverme el problema

La imagen no me la sube y tampoco veo como se sube un fichero, os intentaré explicar lo mejor que pueda mi problema. En una hoja Excel tengo hallados los pagos por formas de pago: SUMAR.SI(D1:D16;"Efectivo";B1:B16), y...
1 respuesta

¿Cómo usar un excel con macros desde varios ordenadores?

A tod@s! Tengo una aplicación en excel para introducir datos y visualizarlos con diferentes formularios creados. Lo que quiero hacer es: 1 Que ese libro este alojado en un sitio común y que lo puedan abrir desde varios ordenadores. 2º Que se pueda...
3 respuestas

Error en macro al ejecutar el botón aceptar

Necesitaría la colaboración para resolver el error que sucede al ejecutar el botón aceptar Set mifila = Hoja2.ListObjects(1).ListRows.Add Lo que yo agregue solamente a la base fue una columna al inicio ("A") anteriormente se llamaba Tabla6 y yo ahora...
1 respuesta

Detectar cambios en tabla dinámica

Tengo una hoja donde se van actualizando datos mediante una tabla dinámica. ¿Cómo detecto cuando se producen cambios (sólo en la parte de la tabla dinámica) para ejecutar otra macro en la misma hoja?
1 respuesta

Macro con combinación de teclas

Acudo aquí buscando ayuda, ¿Cómo crear una macro que genere una combinación de teclas? NO se trata de asignar una macro a una combinación de teclas, es todo lo contrario. El problema radica en que tengo una macro que rellena ciertas celdas con...
1 respuesta

Pasar datos de listbox a hoja con decimales

Como están estimados maestros y maestras, una vez mas solicitando vuestra experta ayuda. Tengo un formulario que busca datos entre 2 fechas desde 2 textbox, carga en listbox lo filtrado, en la columna 2 del listbox carga valores con formato de 2...
1 respuesta

Una macro que de aviso sobre vencimiento de una cedula de identidad

Tengo una hoja de calculo de 6 columnas en donde la columna A es fecha de vencimiento, las columnas B, C, y D son apellidos paterno, Materno u nombres, la columna E es el numero de cedula de identidad Con Formato ##.###.###-# la columna F es lo...
1 respuesta

Error decimales en hoja de excel

Tengo un albarán de varios productos que no vienen desglosado el iva En una hoja Excel introduzco el precio, con la formula sumar el precio lo desgloso en base imponible y el iva paracque me dé el precio del producto pero cuando sumo el total de...
4 respuestas

Filtrar información y luego pasar a otro libro

Tengo una macro que copia y pega del libro llamado Origen y Hoja1, dónde este está cerrado, al libro Destino y Hoja 2 de la siguiente manera: Sub importar() Application.ScreenUpdating = False Application.Calculation = xlCalculationManual...
1 respuesta