Abrir videos de windows media desde access
Lo que pretendo es guardar en una tabla las rutas a diferentes videos que tengo en una carpeta en el escritorio y que una vez pinches en la ruta me los abra. Guardé el campo ruta como hipervínculo, pero al pinchar en él, me sale un mensaje de advertencia de problema de seguridad, igualmente le doy a continuar y me pone que no se puede abrir el archivo especificado ¿alguna sugerencia?
1 respuesta
Respuesta de Eduardo Pérez Fernández
Observe este formulario que utilizo en mis programas donde enseño el manejo el software, consta de:
1 Formulario
1 cuadro de lista (requiere de la tabla donde está el nombre de los videos) y
1 control Active X Windows Media Player
Al hacer clic sobre un video de la lista se muestra en el control Active X.
Código del formulario en general
Option Compare Database
Option Explicit
Dim flagvideo As Boolean
Private Sub cmdParar_Click()
If Me.miplayer.URL <> "" Then
If MsgBox("¿Está seguro que desea suspender el video?", vbYesNo + vbQuestion + vbDefaultButton1, "SIFACAR") = vbYes Then
Me.miplayer.URL = ""
flagvideo = False
End If
End If
End Sub
Private Sub Form_Open(Cancel As Integer)
Me.miplayer.URL = ""
End Sub
Private Sub lstvideos_DblClick(Cancel As Integer)
On Error GoTo hay_error
Dim str_path As String
If flagvideo = True Then
If MsgBox("Debe detener antes el video en curso." & vbCrLf & vbCrLf & "¿Lo desea detener?", vbQuestion + vbYesNo + vbDefaultButton2, "Sifacar") = vbNo Then
Exit Sub
Else
Me.miplayer.URL = ""
flagvideo = False
End If
End If
str_path = CurrentProject.Path & "\Videos\" & Me.lstvideos.Column(2)
Me.miplayer.URL = str_path
If Err.Number = 0 Then
flagvideo = True
End If
hay_error_exit:
Exit Sub
hay_error:
MsgBox Err.Number & " " & Err.Description, vbCritical, "Sifacar"
Resume hay_error_exit
End Sub
Private Sub cmdSalir_Click()
On Error GoTo Err_cmdSalir_Click
If flagvideo = True Then
Me.miplayer.URL = ""
flagvideo = False
End If
DoCmd.Close
Exit_cmdSalir_Click:
Exit Sub
Err_cmdSalir_Click:
MsgBox Err.Description
Resume Exit_cmdSalir_Click
End Sub
