Macro en Excel para registrar movimientos de mercancía
Podrían ayudarme con una macro que haga lo siguiente:
Tengo 4 tablas:
Almacén 1
Almacén 2
Almacén 3
Almacén 4
Cada una de las tablas tiene tres encabezados:
Encabezado 1: tarima
Encabezado 2: código
Encabezado 3: cantidad
Tarima código cantidad
Actualmente hago el proceso manual de ingresar los datos dependiendo en donde va cada código, si el código va en el almacén 2, 3, 4, o 1, según sea el caso, hago el registro manual.
Si tengo el código 1211, y dice el formato de registro que lo ubicaron en el almacén 3, me voy a la tabla del almacén 3 y hago el proceso de registro, tarima 31a2, código 1211, cantidad 100.
Y así sucesivamente lo hago con los 30 o 50 movimientos diarios de mercancía.
Podrían ayudarme a automatizar el proceso de registro
Si tengo el código 1211, y dice el formato de registro que lo ubicaron en el almacén 3, me voy a la tabla del almacén 3
¿En dónde tienes los datos? ¿En un papel físico? ¿Y de ahí tomas los datos y los capturas en excel?
En excel puedes crear un formulario de captura (userform), ahí puedes capturar los datos: almacén, tarima, código y cantidad. Presionar un botón y con una macro, automáticamente pasar los datos a la hoja correspondiente.
Te puedo ayudar con el userform. Puedes subir tu archivo a la nube, por ejemplo a google drive. Si tienes datos confidenciales, los puedes cambiar por datos genéricos, lo importante es que se conserve el diseño y estructura de las hojas.
Buen día, gracias por su amable atención, si tengo el registro en un papel físicamente y después capturó los datos en Excel.
Este sería el archivo:
https://docs.google.com/spreadsheets/d/105tgI2EjD-xXXO3SW5lq2gh7OgIQdMD2/edit?usp=drivesdk&ouid=103156279090003477447&rtpof=true&sd=true
por lo pronto es la información que manejo, falta agregar la fecha de entrada y salida, ahorita solamente pongo en color rojo las celdas donde se encontraba el material.
agradezco la atención, esperando sea la información requerida.
Te envié una solicitud para poder descargar el archivo...
Realiza lo siguiente:
1. Crea un botón en tu hoja
2. En módulo pon la siguiente macro:
Sub abrir() UserForm1.Show End Sub
3. Asigna la la macro "abrir" al botón.
4. Crea un userform con un combobox, 3 textbox y commandbutton.
5. Pon el siguiente código en el userform
Private Sub CommandButton1_Click()
If ComboBox1.ListIndex = -1 Or ComboBox1.Value = "" Then
MsgBox "Selecciona un almacén"
ComboBox1.SetFocus
Exit Sub
End If
If TextBox1.Value = "" Then
MsgBox "Captura la tarima"
TextBox1.SetFocus
Exit Sub
End If
If TextBox2.Value = "" Then
MsgBox "Captura el código"
TextBox2.SetFocus
Exit Sub
End If
If TextBox3.Value = "" Then
MsgBox "Captura la cantidad"
TextBox3.SetFocus
Exit Sub
End If
'
Dim lr As Long
Dim f As Range
Dim col As Long
Set f = Range("2:2").Find(ComboBox1.Value, , xlValues, xlWhole, , , False)
If Not f Is Nothing Then
col = f.Column
lr = ActiveSheet.Columns(col).Find("*", , xlValues, , xlByRows, xlPrevious).Row + 1
Cells(lr, col).Value = TextBox1.Value
Cells(lr, col + 1).Value = TextBox2.Value
Cells(lr, col + 2).Value = TextBox3.Value
MsgBox "Registro creado"
ComboBox1.Value = ""
TextBox1.Value = ""
TextBox2.Value = ""
TextBox3.Value = ""
End If
End Sub
'
Private Sub UserForm_Activate()
Dim c As Range
'
For Each c In Range("B2", Cells(2, Columns.Count).End(1))
If c.Value <> "" Then
ComboBox1.AddItem c.Value
End If
Next
ComboBox1.SetFocus
End Sub6. Regresa a la hoja de excel.
7. Presiona el botón de la hoja, en automático se abre el userform
8. Captura el almacén, la tarima, el código y la cantidad.
9. Presiona el botón.
10. La macro escribirá los datos en el almacén correspondiente.
Te anexo el archivo con todo lo anterior.
https://drive.google.com/file/d/1YmAsV5RrX3_atLwt77-_EBo6eCMvYmTX/view?usp=sharing
[No olvides valorar la respuesta.
sal u dos. Dante Amor
