Numeración automática de 3 condiciones

Hola expertos, tengo una duda y acudo a vosotros ya que no puedo resolverla por mi mismo.
Tengo tres columnas ( A B C) que se corresponden a las coordenadas POR Y y Z de un punto en el espacio.
Tengo un listado de coordenadas en las cuales se repiten varias veces las mismas coordenadas.
Hasta ahora numeraba los puntos a mano, haciendo autofiltro y activando uno por uno para saber los que se repetían, pero debido al numero de puntos ya no es viable.
En resumen, necesito una orden que me identifique las tres coordenadas de cada fila y la numere si no se repiten anteriormente, y si se repite darle el valor que se le dio anteriormente...
Pondré un breve ejemplo:
A B C D
1 1 1 1
0.25 1 1 2
3 2 1.5 3
1 1 1 1
En la columna DE pocría la numeración automática. Como A4 B4 C4 coinciden los valores con A1 B1 C1, numero estas tres coordenadas como 1 (D4)
Espero vuestra sabia respuesta.
Un saludo.

1 Respuesta

Respuesta
1
Te dejo un procedimiento que hace lo que buscas. Espero que te sirva bien.
Un saludo
Option Explicit
Sub numerarCeldas()
    Dim numFilas As Long
    Dim i As Long
    Dim j As Long
    Dim n As Long
    ' Buscamos el número de filas que tiene la tabla
numFilas = buscarUltimoNumeroFila()
    ' Definimos unas matrices para almacenar los valores
    ReDim matDatos(1 To numFilas, 1 To 3) As Double
    ReDim matNum(1 To numFilas) As Long
    ' Leemos los datos
    For i = 1 To numFilas
        matDatos(i, 1) = Cells(i, 1)
        matDatos(i, 2) = Cells(i, 2)
        matDatos(i, 3) = Cells(i, 3)
    Next i
    ' Asignamos un valor a cada fila
    n = 0
    For i = 1 To numFilas
        For j = 1 To i - 1  ' Comprobamos si ya existe
            If matDatos(i, 1) = matDatos(j, 1) And _
               matDatos(i, 2) = matDatos(j, 2) And _
               matDatos(i, 3) = matDatos(j, 3) Then Exit For
        Next j
        If j > i - 1 Then
            ' No hay otra igual
            n = n + 1
            matNum(i) = n
          Else
            ' Está repetido
            matNum(i) = matNum(j)
        End If
    Next i
    ' Ponemos los valores en la columna D
    For i = 1 To numFilas
        Cells(i, 4) = matNum(i)
    Next i
End Sub
Private Function buscarUltimoNumeroFila() As Long
    Dim i As Long
    i = 1
    Do While Cells(i, 1) <> ""
        i = i + 100
    Loop
    Do While Cells(i, 1) = ""
        i = i - 1
        If i = 0 Then Exit Do
    Loop
    buscarUltimoNumeroFila = i
End Function
Perfecto! Gracias por la macro, no podía adaptarse mejor a mis cálculos.
Quisiera hacerte una consulta más.
Estas coordenadas son el inicio y fin de las aristas de una figura geométrica.
Necesito ordenar de menor a mayor el orden de los nudos, ejemplo
G H I
1 1 2
2 2 3
3 5 7
En la columna G (aristas), en H(nudo1) y en I (nudo 2) se deben de ordenar los datos obtenidos en la macro anterior,
¿Se podría implementar esto en dicha macro?
He intentado hacer esto con la orden Buscarh (BUSCARV($G2;$D$2:$E$241;2;1) pero solo me encuentra un valor (el primero que encuentra).
Muchísimas gracias.
Un saludo.
Supongo que sería ordenar la matriz. Pero hay que tener en cuenta que, una vez ordenados los datos, hay que reescribir tu tabla.
El código completo sería algo así:
Option Explicit
Sub numerarCeldas()
    Dim numFilas As Long
    Dim i As Long
    Dim j As Long
    Dim n As Long
    ' Buscamos el número de filas que tiene la tabla
numFilas = buscarUltimoNumeroFila()
    ' Definimos unas matrices para almacenar los valores
    ReDim matDatos(1 To numFilas, 1 To 3) As Double
    ReDim matNum(1 To numFilas) As Long
    ' Leemos los datos
    For i = 1 To numFilas
        matDatos(i, 1) = Cells(i, 1)
        matDatos(i, 2) = Cells(i, 2)
        matDatos(i, 3) = Cells(i, 3)
    Next i
    ' Ordenamos los datos
    ordenarDatosMatriz matDatos()
    ' Asignamos un valor a cada fila
    n = 0
    For i = 1 To numFilas
        For j = 1 To i - 1  ' Comprobamos si ya existe
            If matDatos(i, 1) = matDatos(j, 1) And _
               matDatos(i, 2) = matDatos(j, 2) And _
               matDatos(i, 3) = matDatos(j, 3) Then Exit For
        Next j
        If j > i - 1 Then
            ' No hay otra igual
            n = n + 1
            matNum(i) = n
          Else
            ' Está repetido
            matNum(i) = matNum(j)
        End If
    Next i
    ' Ponemos los valores en la columna D
' (ahora también escribimos los datos de las columnas A, B y C
    For i = 1 To numFilas
        Cells(i, 1) = matDatos(i, 1)
        Cells(i, 2) = matDatos(i, 2)
        Cells(i, 3) = matDatos(i, 3)
        Cells(i, 4) = matNum(i)
    Next i
End Sub
Private Function buscarUltimoNumeroFila() As Long
    Dim i As Long
    i = 1
    Do While Cells(i, 1) <> ""
        i = i + 100
    Loop
    Do While Cells(i, 1) = ""
        i = i - 1
        If i = 0 Then Exit Do
    Loop
    buscarUltimoNumeroFila = i
End Function
Sub ordenarDatosMatriz(ByRef matDatos() As Double)
    Dim i As Integer
    Dim j As Integer
    Dim n As Integer
    Dim aux As Double
    Dim snCambiar As Boolean
    n = UBound(matDatos, 1)
    For i = 1 To n - 1
        For j = 1 To n - i
            ' Cambiaremos si el primer valor es mayor que el primer valor de la siguiente
            ' fila o, siendo igual, el segundo valor es mayor que el de la siguente fila
            ' o, siendo los dos primeros iguales, el tercer valor de la fila es mayor que
            ' el tercer valor de la fila siguiente.
            snCambiar = matDatos(j, 1) > matDatos(j + 1, 1) Or _
                       (matDatos(j, 1) = matDatos(j + 1, 1) And _
                        matDatos(j, 2) > matDatos(j + 1, 2)) Or _
                       (matDatos(j, 1) = matDatos(j + 1, 1) And _
                        matDatos(j, 2) = matDatos(j + 1, 2) And _
                        matDatos(j, 3) > matDatos(j + 1, 3))
            If snCambiar Then
                aux = matDatos(j, 1)
                matDatos(j, 1) = matDatos(j + 1, 1)
                matDatos(j + 1, 1) = aux
                aux = matDatos(j, 2)
                matDatos(j, 2) = matDatos(j + 1, 2)
                matDatos(j + 1, 2) = aux
                aux = matDatos(j, 3)
                matDatos(j, 3) = matDatos(j + 1, 3)
                matDatos(j + 1, 3) = aux
            End If
        Next j
    Next i
End Sub

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas

Detectar cambios en tabla dinámica

Tengo una hoja donde se van actualizando datos mediante una tabla dinámica. ¿Cómo detecto cuando se producen cambios (sólo en la parte de la tabla dinámica) para ejecutar otra macro en la misma hoja?
1 respuesta

Macro con combinación de teclas

Acudo aquí buscando ayuda, ¿Cómo crear una macro que genere una combinación de teclas? NO se trata de asignar una macro a una combinación de teclas, es todo lo contrario. El problema radica en que tengo una macro que rellena ciertas celdas con...
1 respuesta

Pasar datos de listbox a hoja con decimales

Como están estimados maestros y maestras, una vez mas solicitando vuestra experta ayuda. Tengo un formulario que busca datos entre 2 fechas desde 2 textbox, carga en listbox lo filtrado, en la columna 2 del listbox carga valores con formato de 2...
1 respuesta

Una macro que de aviso sobre vencimiento de una cedula de identidad

Tengo una hoja de calculo de 6 columnas en donde la columna A es fecha de vencimiento, las columnas B, C, y D son apellidos paterno, Materno u nombres, la columna E es el numero de cedula de identidad Con Formato ##.###.###-# la columna F es lo...
1 respuesta

Error decimales en hoja de excel

Tengo un albarán de varios productos que no vienen desglosado el iva En una hoja Excel introduzco el precio, con la formula sumar el precio lo desgloso en base imponible y el iva paracque me dé el precio del producto pero cuando sumo el total de...
4 respuestas

Filtrar información y luego pasar a otro libro

Tengo una macro que copia y pega del libro llamado Origen y Hoja1, dónde este está cerrado, al libro Destino y Hoja 2 de la siguiente manera: Sub importar() Application.ScreenUpdating = False Application.Calculation = xlCalculationManual...
1 respuesta

Código VBA para ocultar formulario

Tengo un formulario para colocar USUARIO y CONTRASEÑA, lo cual lo hace bie, pero requiero que una vez se introduzca los datos correctos, el formulario se oculte y me redirecciona u "hoja1" Intenté ocultarlos con esta instrucción Private Sub...
2 respuestas

Diferentes Formato de Fecha en Hoja de Calculo

Pregunta a Elsa Matilde Estoy trabajando en un formulario VB donde los 2 TextBox veo que la fecha tiene formato 01/11/2024, pero cuando pasa los datos desde el formulario a la hoja de trabajo una columna se refleja 01/11/24 y la otra columna...
1 respuesta

Como insertar de forma separada registros en diferentes columnas en una misma fila

Estoy tratando de realizar un formulario de registro de asistencia que registre la hora de entrada, la hora de inicio y fin del cafe, la hora de inicio y fin del amuerzo y la hora de la salida. Hay unos botones de opción que seleccionan el tipo de...
1 respuesta

Macro para copiar valor de texbox a hoja2

Necesito un poco de ayuda con una macro estoy aprendiendo mi duda es la siguiente tengo una hoja llamada Principal utilizo un botón de comando para llamar a userform1 el cual tiene varios texbox numerados 1,2,3,4,5,6,7,8,9,10,11 aquí utilizo solo...
1 respuesta