Formula consultav numero o texto
Un placer dirigirme a ustedes nuevamente.
Bueno necesito de su ayuda, con la siguiente formula
=SI((CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO)/100)=0,"", CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO)/100)
Como ya sabrán esta formula busca en la matriz b6:cy65 el numero
que se encuentra en la intentar 14, y el agregado =0,"", es porque
necesito que si no hay cantidad no aparezca nada ... Esta explicación
esta de mas, eso lo se.
El problema esta en que en algunos casos necesito ingresar una abreviatura o una letra (texto) nsp no es un numero y me sale un error que dice #¡Valor! . O si ingreso un asterisco o cualquier cosa que no se numero
Lo que quiero es que me ayuden a arreglar la formula que me permita ingresar un numero o un texto...
1 Respuesta
Si entendí bien, lo que necesitas es que lo que está en la columna 14, si es número te lo traiga, si es texto, que no te aparezca nada, si es así, la fórmula sería:
=SI(T(CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO))="",CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO)/100,"")
Lo primero que verifico es si el contenido de 14 es Texto, si me regresa "", es un número, entonces que me ponga el número de 14 y lo divida entre 100, de lo contrario que no ponga nada "".
Espero que te funcione, de lo contrario con gusto lo podemos revisar.
gracias por darme contestación:
no.......... lo que necesitaba es que lo que esta en la columna 14 me lo traiga ya sea numero o texto, porque el problema es cuando escribo (NSP) texto me sale el error,,, pero con una travesura logre el objetivo y fue quitando /100 y le di formato de porcentaje a la matriz donde están los datos de origen...
ahora bien no te desanimare trata de darme la respuesta con el /100 y algo mas aprovechando la consulta siempre relacionado con el mismo caso.
a la par de la formula que te consulto, tengo esta otra formula con problemas:
=SI(D15="","",SI(D15>90%,"Sobresaliente",SI(D15>79%,"Muy Bueno",SI(D15>59%,"Bueno", SI(D15>=0%,"No Satisfactorio")))))
el problema es que al ingresar NSP (texto) me aparece "sobresaliente" no se porque si sobresaliente esta especificado que es >90% y yo quiero que cuando tenga NSP que NO aparezca nada, que la celda este vacía completamente.
agradeceré tu ayuda, ya que la necesito.
Puedes usar la misma fórmula, si el valor de la columna es Texto, no lo dividas / 100.
=SI(T(CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO))="",CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO)/100,CONSULTAV($G$10,'Cuadro de Actas'!$B$6:$CY$65,14,FALSO))
Con respecto a tu segunda pregunta, estás preguntando si D15="", significa que solamente si D15 es igual a blanco, si tiene una letra, entonces ya no es igual y se va por el valor falso.
Te sugiero que pongas en otras columnas por ejemplo J y K los valores:
0 No satisfactorio
59 Bueno
79 Muy bueno
90 Sobresaliente
Nota: los tienes que poner en ese orden.
Luego en la celda donde quieres el resultado pon la siguiente función:
=CONSULTAV(D15,J:K,2,VERDADERO)
De esta forma puedes agregar más valores, siempre de forma ascendente, a tu cuadro de calificaciones y es más sencillo que poner varios SI.
Por último si en D15 tienes letras, la función te va a regresar #N/A, para evitar esto, tendrías que poner la fórmula:
=SI(ESERROR(CONSULTAV(D15, J:K, 2, VERDADERO)),"", CONSULTAV(D15, J:K, 2, VERDADERO))
P.D.
Me puedes decir qué significa "NSP"
bueno antes de dar respuesta a la pregunta, agradecerte grandemente, no le hallaba ni pies ni cabeza, esas columnas auxiliar fue una salida fenomenal, aaaaaa otra cosa mi cuadro termina en la columna I al sugerirme J y K, me asuste, me diste la respuesta como que conocías el documento.
nsp = no se presento ( ya que son notas de exámenes)
gracias s s s s s s s s s s s s s . . . excelente
