¿Como enlazar Combobox dependientes y unir con Textbox al finalizar filtro?

Soy bastante novato y estoy aprendiendo sobre este lenguaje. Tengo un formulario en cual tengo 6 combobox los cuales están enlazados entre sí, es decir, cuando selecciono algún valor en el primer combobox este condiciona el segundo y así sucesivamente (filtro en cascada) y la idea es que al finalizar me arroje los valores (la celda siguiente) de ese filtro en un textbox (en este caso el promedio).

Mi problema es que cuando realizo los últimos pasos (filtros de años y meses) no me arrojan valores, creo que es por la variable numérica, pero como mencione con anterioridad estoy aprendiendo este lenguaje el cual no manejo, me podría explicar o aconsejar cambios para poder obtener buenos resultados

De antemano muchas gracias

Saludos cordiales

Lo que pretendo hacer y como están ordenados los datos es así:

y esta es la sintaxis 

Private Sub ComboBox5_Change()
ComboBox6.Clear
uf = Sheets("Datos").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To uf
If Sheets("Datos").Cells(i, "D") = ComboBox4 And _
Sheets("Datos").Cells(i, "E") = ComboBox5 Then
AddItem ComboBox6, Sheets("Datos").Cells(i, "F")
End If
Next
End Sub

Private Sub ComboBox4_Change()
ComboBox5.Clear
uf = Sheets("Datos").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To uf
If Sheets("Datos").Cells(i, "C") = ComboBox3 And _
Sheets("Datos").Cells(i, "D") = ComboBox4 Then
AddItem ComboBox5, Sheets("Datos").Cells(i, "E")
End If
Next
End Sub
Private Sub ComboBox3_Change()
ComboBox4.Clear
uf = Sheets("Datos").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To uf
If Sheets("Datos").Cells(i, "B") = ComboBox2 And _
Sheets("Datos").Cells(i, "C") = ComboBox3 Then
AddItem ComboBox4, Sheets("Datos").Cells(i, "D")
End If
Next
End Sub

Private Sub ComboBox2_Change()
ComboBox3.Clear
uf = Sheets("Datos").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To uf
If Sheets("Datos").Cells(i, "A") = ComboBox1 And _
Sheets("Datos").Cells(i, "B") = ComboBox2 Then
AddItem ComboBox3, Sheets("Datos").Cells(i, "C")
End If
Next

End Sub
Private Sub ComboBox1_Change()
ComboBox2.Clear
uf = Sheets("Datos").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To uf
If Sheets("Datos").Cells(i, "A") = ComboBox1 Then
AddItem ComboBox2, Sheets("Datos").Cells(i, "B")
End If
Next

End Sub

Private Sub ComboBox6_Change()
f = ComboBox5.ListIndex + 2
TextBox1.Value = Sheets("Datos").Cells(f, "G")
TextBox1 = Format(TextBox1, "#,###.000")

End Sub

Private Sub CommandButton1_Click()
ComboBox1.Clear
uf = Sheets("Datos").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To uf
AddItem ComboBox1, Sheets("Datos").Cells(i, "A")
Next
TextBox1.Value = Empty

End Sub

Sub AddItem(cmbBox As ComboBox, sItem As String)
For i = 0 To cmbBox.ListCount - 1
Select Case StrComp(cmbBox.List(i), sItem, vbTextCompare)
Case 0: Exit Sub
Case 1: cmbBox.AddItem sItem, i: Exit Sub
End Select
Next
cmbBox.AddItem sItem
End Sub

1 Respuesta

Respuesta
2

Te anexo la macro completa para cargar los 6 combos dependientes y por último un dato en el textbox1.

Tienes que reemplazar tu macro por esta macro. Cuando modificas un combo, tienes que revisar los datos de todas las columnas, en el código que enviaste, por ejemplo, para el combo 4, sólo revisas el combo 3 y 4, y debes revisar el 1,2,3 y 4, de lo contrario estarás cargando información errónea.

Prueba esta macro con mucho más información para que lo revises.

Otro detalle que debes considerar, es que si tienes 2 ó más registros iguales en todas sus columnas, en el textbox1 solamente te pondrá el dato del primer registro.

Private Sub ComboBox1_Change()
    cargar 2
End Sub
Private Sub ComboBox2_Change()
    cargar 3
End Sub
Private Sub ComboBox3_Change()
    cargar 4
End Sub
Private Sub ComboBox4_Change()
    cargar 5
End Sub
Private Sub ComboBox5_Change()
    cargar 6
End Sub
Private Sub ComboBox6_Change()
'Por.Dante Amor
    For i = 2 To Range("A" & Rows.Count).End(xlUp).Row
        For j = 1 To 6
            valor = IIf(IsNumeric(Controls("ComboBox" & j)), _
                Val(Controls("ComboBox" & j)), Controls("ComboBox" & j))
            If Cells(i, j) = valor Then
                igual = True
            Else
                igual = False
                Exit For
            End If
        Next
        If igual Then Exit For
    Next
    If igual Then TextBox1 = Cells(i, j)
End Sub
Private Sub UserForm_Activate()
'Por.Dante Amor
    For i = 2 To Range("A" & Rows.Count).End(xlUp).Row
        agregar ComboBox1, Cells(i, "A")
    Next
End Sub
Sub agregar(combo As ComboBox, dato As String)
'Por.Dante Amor
    For i = 0 To combo.ListCount - 1
        Select Case StrComp(combo.List(i), dato, vbTextCompare)
            Case 0: Exit Sub 'ya existe en el combo y ya no lo agrega
            Case 1: combo.AddItem dato, i: Exit Sub 'Es menor, lo agrega antes del comparado
        End Select
    Next
    combo.AddItem dato 'Es mayor lo agrega al final
End Sub
Sub cargar(ini)
'Por.Dante Amor
    TextBox1 = ""
    For i = ini To 6
        Controls("ComboBox" & i) = ""
        Controls("ComboBox" & i).Clear
    Next
    For i = 2 To Range("A" & Rows.Count).End(xlUp).Row
        For j = 1 To ini - 1
            valor = IIf(IsNumeric(Controls("ComboBox" & j)), _
                Val(Controls("ComboBox" & j)), Controls("ComboBox" & j))
            If Cells(i, j) = valor Then
                igual = True
            Else
                igual = False
                Exit For
            End If
        Next
        If igual Then agregar Controls("ComboBox" & ini), Cells(i, ini)
    Next
End Sub

Estimado Dante

Gracias por tu pronta respuesta, efectivamente me funciona la macros que  me otorgas, pero pido un poco más de tu ayuda y experiencia, se me olvidó mencionar que los datos los tengo en otra hoja (hoja2) y el filtro lo hago en la hoja1 ¿es mucho el cambio que habría que hacer en la macro?

Otra consulta, no quiero usar un userform sino que los combobox directo en la hoja de Excel  como se muestra en la imagen que adjunte anteriormente ¿Es posible hacer eso?

Nuevamente agradezco tu tiempo y tus respuestas

Saludo cordiales

Te anexo la macro para cargar los combos en la hoja. El último detalle es que el año y el mes se tienen que verificar como valores numéricos

Private Sub ComboBox1_Change()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    ComboBox2. Clear
    ComboBox3. Clear
    ComboBox4. Clear
    ComboBox5. Clear
    ComboBox6. Clear
    TextBox1 = ""
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        If h2.Cells(i, "A") = ComboBox1 Then
            agregar ComboBox2, h2.Cells(i, "B")
        End If
    Next
End Sub
'
Private Sub ComboBox2_Change()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    ComboBox3.Clear
    ComboBox4.Clear
    ComboBox5.Clear
    ComboBox6.Clear
    TextBox1 = ""
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        If h2.Cells(i, "A") = ComboBox1 And _
           h2.Cells(i, "B") = ComboBox2 Then
            agregar ComboBox3, h2.Cells(i, "C")
        End If
    Next
End Sub
'
Private Sub ComboBox3_Change()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    ComboBox4.Clear
    ComboBox5.Clear
    ComboBox6.Clear
    TextBox1 = ""
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        If h2.Cells(i, "A") = ComboBox1 And _
           h2.Cells(i, "B") = ComboBox2 And _
           h2.Cells(i, "C") = ComboBox3 Then
            agregar ComboBox4, h2.Cells(i, "D")
        End If
    Next
End Sub
'
Private Sub ComboBox4_Change()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    ComboBox5.Clear
    ComboBox6.Clear
    TextBox1 = ""
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        If h2.Cells(i, "A") = ComboBox1 And _
           h2.Cells(i, "B") = ComboBox2 And _
           h2.Cells(i, "C") = ComboBox3 And _
           h2.Cells(i, "D") = ComboBox4 Then
            agregar ComboBox5, h2.Cells(i, "E")
        End If
    Next
End Sub
'
Private Sub ComboBox5_Change()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    ComboBox6.Clear
    TextBox1 = ""
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        If h2.Cells(i, "A") = ComboBox1 And _
           h2.Cells(i, "B") = ComboBox2 And _
           h2.Cells(i, "C") = ComboBox3 And _
           h2.Cells(i, "D") = ComboBox4 And _
           h2.Cells(i, "E") = Val(ComboBox5) Then
            agregar ComboBox6, h2.Cells(i, "F")
        End If
    Next
End Sub
'
Private Sub ComboBox6_Change()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    TextBox1 = ""
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        If h2.Cells(i, "A") = ComboBox1 And _
           h2.Cells(i, "B") = ComboBox2 And _
           h2.Cells(i, "C") = ComboBox3 And _
           h2.Cells(i, "D") = ComboBox4 And _
           h2.Cells(i, "E") = Val(ComboBox5) And _
           h2.Cells(i, "F") = Val(ComboBox6) Then
           TextBox1 = h2.Cells(i, "F")
        End If
    Next
End Sub
'
Sub agregar(combo As ComboBox, dato As String)
'Por.Dante Amor
    For i = 0 To combo.ListCount - 1
        Select Case StrComp(combo.List(i), dato, vbTextCompare)
            Case 0: Exit Sub 'ya existe en el combo y ya no lo agrega
            Case 1: combo.AddItem dato, i: Exit Sub 'Es menor, lo agrega antes del comparado
        End Select
    Next
    combo.AddItem dato 'Es mayor lo agrega al final
End Sub
'
Private Sub ComboBox1_DropButtonClick()
'Por.Dante Amor
    Set h2 = Sheets("Hoja2")
    'ComboBox1.Clear
    For i = 2 To h2.Range("A" & Rows.Count).End(xlUp).Row
        agregar ComboBox1, h2.Cells(i, "A")
    Next
End Sub

Saludos.Dante Amor

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas

Como guardar el valor de un textbox dependiendo de la selección de un combobox

Tengo un formulario y dentro de el tengo un textbox vacío y un combobox con varias opciones que toma de la fila 1. Se supone que en este formulario tengo que elegir una opción del combobox y en seguida agregarle una descripción, me gustaría saber...
2 respuestas

Filtrar datos de una base con combobox

Tengo una base que necesito filtrar mediante 3 combobox eliminando los datos repetidos en cada uno de los combobox, al momento de seleccionar el primer combobox1 debe filtrar los datos de la siguiente columna y agregarla al combobox2 y asi con el...
1 respuesta

Vincular dos combobox y un textbox después del segundo combo box

Antemano aclara soy principiante. Tengo un problema tengo dos combobox (codigos de productos) vinculados el primero del segundo y por otro lado tengo otro combobox ( dodigos de producto) vinculado con otros textbox (descripción del producto), Las dos...
1 respuesta

Codigo VBA para realizar búsqueda de datos de una hoja de excel en un formulario, seleccionando de un combobox?

Todo expertos, mi duda es la siguiente: Tengo 1 hoja de excel con nombres de personas en la primera columna y en 11 columnas mas todos los datos correspondientes al nombre de la persona, he hecho una "Pagina inicio" que permite abrir un formulario en...
2 respuestas

8 combobox dependientes enlazados

Estimados expertos tengo el sigiente problema quiero realizar una macro en donde tenga 8 combobox en los cuales quiero desplegar la siguiente informacion tengo el sgte codigo Public ufila As Integer Private Sub ComboBox1_Change() ComboBox2.Clear...
1 respuesta

Copiar datos a hojas desde formulario con 2 paginas

Tengo un UserForm que quiero utilizar como formulario, para introducir datos a dos hojas distintas (Hoja1 y Hoja2); de tal manera que los datos que introduzca en los distintos TextBox y ComboBox, de la "Page1" del UserForm se copien en la Hoja1; y...
1 respuesta

Como hacer Combobox dependientes en un formulario ?

Tengo un formulario a través del cual introduzco "filas" de una base de datos a diferentes combobox, mi objetivo es, si yo cambio el valor de uno de estos combobox, que automáticamente todos los demás se me cambien al valor correspondiente en la base...
2 respuestas

Formulario en Excel con Varios Combobox Dependientes

Tengo un Archivo de Excel, en el que manejo Datos de Vehículos, marca, modelo, año, Descripción de Producto, Código de Parte, y Código de Intercambio 1 y código de Intercambio 2, como puedo hacer que en un formulario, al Elegir, La marca, me filtre...
1 respuesta

Macro Para actualizar Dato de un Textbox

Para: Dante Tengo un formulario en la que ingreso datos con un textbox que jala el valor de una celda de cierta columna el inconveniente que tengo es que al guardar nuevos datos a la hoja; en el textbox de mi formulario debería actualizarse...
2 respuestas

Comboboxs dependientes en una hoja de excel

Tengo en una hoja de excel la Columna A perteneciente al Distribuidor1 con la siguiente informacion; Distribuidor1 Departamento1 Departamento2 Etc En la otra columna se encuentra el Distribuidor2, con el departamento 3, Departamento4, etc. Y así...
3 respuestas