¿Como copiar los datos de 36 pestañas en una sola?
Tengo 36 pestañas, configuradas de la siguiente forma:
9 columnas iguales para las 36 pestañas, la primera fila corresponde a el titulo de cada columna, los datos empiezan en A2, pero no tienen una fila determinada para termino (hay pestañas que en un mes en particular quedan sin registros mientras que al otro mes puede ocupar 100 filas).
Me gustaría copiar los datos de estas 36 pestañas, a una pestaña (37) llamada "todo", donde la primera pestaña se copia primero, luego debajo de los datos de la primera, si es que corresponde, debiesen ir los datos de la segunda, y así hasta la 36.
2 Respuestas
Te anexo la macro para copiar las hojas a la hoja "todo", si la hoja que va a concentrar le quieres poner otro nombre, cambia el nombre en esta línea
Set h1 = Sheets("todo")
Sub Copiar36()
'Por.Dante Amor
Set h1 = Sheets("todo")
For Each h In Sheets
If h.Name <> h1.Name Then
u = h.Range("A" & Rows.Count).End(xlUp).Row
If u > 1 Then
u1 = h1.Range("A" & Rows.Count).End(xlUp).Row + 1
h.Rows(2 & ":" & u).Copy h1.Range("A" & u1)
End If
End If
Next
MsgBox "Datos copiados a la hoja: " & h1.Name, vbInformation
End SubSaludos.Dante Amor
Si es lo que necesitas.
Ok prueba esta macro
Option Explicit
Sub consolidar()
Dim i As Integer
Dim f As Integer
Dim tf As Long
Application.ScreenUpdating = False
For i = 1 To (ThisWorkbook.Sheets.Count - 1)
f = Application.WorksheetFunction.CountA(Sheets(i).Range("A:A"))
If f > 1 Then
Sheets(i).Activate
Sheets(i).Range("A2:I" & f).Copy
tf = Application.WorksheetFunction.CountA(Sheets(ThisWorkbook.Sheets.Count).Range("A:A")) + 1
Sheets(ThisWorkbook.Sheets.Count).Activate
Sheets(ThisWorkbook.Sheets.Count).Range("A" & tf).Select
ActiveSheet.Paste
Application.CutCopyMode = False
End If
DoEvents
Next
Application.ScreenUpdating = True
MsgBox "Copiado", vbInformation
End Sub
Pegara los datos de todas las hojas según la estructura que informas los datos se envían a la última hoja del libro.