Cómo buscar valores de una tabla y que me aparezcan en un textbox

H o l a:

Crea en tu userform un commandbutton1 y pon el siguiente código:

Private Sub CommandButton1_Click()
'Por.Dante Amor
    If TextBox1 = "" Then
        MsgBox "Escribir un valor en el textbox1"
        Exit Sub
    End If
    TextBox2 = ""
    TextBox3 = ""
    Set h1 = Sheets("Hoja1")
    Set h2 = Sheets("Hoja2")
    Set b = h2.Columns("A").Find(TextBox1, lookat:=xlWhole)
    If Not b Is Nothing Then
        TextBox2 = h2.Cells(b.Row, "B")
        TextBox3 = h2.Cells(b.Row, "C")
    Else
        MsgBox "El nombre no existe"
    End If
End Sub

Funciona de maravilla, muchas gracias y lamento la demora de mi respuesta, habrá manera de que lo busque sin oprimir el botón? osea en cuanto el texbox1 tenga un  dato los demás textbox se llenen? 

Cambia el evento por este:

Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
'Por.Dante Amor
    TextBox2 = ""
    TextBox3 = ""
    Set h2 = Sheets("Hoja2")
    Set b = h2.Columns("A").Find(TextBox1, lookat:=xlWhole)
    If Not b Is Nothing Then
        TextBox2 = h2.Cells(b.Row, "B")
        TextBox3 = h2.Cells(b.Row, "C")
    Else
        MsgBox "El dato no existe"
    End If
End Sub

Captura el dato y presiona la tecla Enter

Disculpa si mi texbox3 es una cantidad en pesos como le agrego ese formato? gracias. 

Puede ser así:

TextBox3 = Format(h2.Cells(b.Row, "C"), "$ * #,##.00")

Perfecto, va de maravilla mi hoja de calculo, lamento la demora de mis respuestas pero tardo en modificar los procesos para que me funcione con mis datos, no se si deba votar esta pregunta y abrir otra pero siento que seria más difícil darme a explicar, si ya encontré al niño y ya me dio la edad y su calificación, ¿cómo puedo hacer para modificar desde mi formulario el texbox de la calificación y que se actualice en la hoja2?