Ubicacion de hoja excel de acuerdo a criterios
Tengo esta macro:
Sub BuscarNumero()
'Por.Dante Amor
num = Hoja14.[TA1]
For h = 1 To 13
Set b = Sheets(h).Cells.Find(num, lookat:=xlWhole)
If Not b Is Nothing Then
cad = cad & "," & Sheets(h).Name
End If
Next
If cad <> "" Then
cad = Mid(cad, 2)
Hoja14.[TB1] = cad
End If
End Sub
Como hago para que su procedimiento cambie haciendo que funcione que todos los numeros que coloque en la columna TA me de todos sus resultados en la columna TB
1 Respuesta
Respuesta de Dante Amor
2
H o l a:
Te anexo la macro actualizada para que recorra todas las filas.
Option Explicit
Sub BuscarNumero()
'Por.Dante Amor
Dim u As Double, i As Double
Dim h1 As Object
Dim h As Integer
Dim cad As String
Dim b As Object
'
Application.ScreenUpdating = False
Application.StatusBar = False
Set h1 = Sheets("Hoja14")
'
h1.Columns("TB").ClearContents
u = h1.Range("TA" & Rows.Count).End(xlUp).Row
For i = 1 To u
Application.StatusBar = "Procesando registro: " & i & " de: " & u
cad = ""
For h = 1 To 13
Set b = Sheets(h).UsedRange.Find(h1.Cells(i, "TA"), lookat:=xlWhole, LookIn:=xlValues)
If Not b Is Nothing Then
cad = cad & ", " & Sheets(h).Name
End If
Next
h1.Cells(i, "TB") = cad
Next
Application.ScreenUpdating = True
Application.StatusBar = False
MsgBox "Fin"
End Sub':) 'S aludos. D a n t e A m o r . R ecuerda valorar la respuesta. G racias ':)
