Comparar columnas y si no son iguales insertar celda en blanco

Te anexo la macro. El resultado quedará en las columnas H e I

Sub Ordenar_Numeros()
'Por.Dante Amor
    Application.ScreenUpdating = False
    j = 0
    ant = ""
    Columns("E:I").Clear
    '
    'Quitar duplicados col B
    u1 = Range("B" & Rows.Count).End(xlUp).Row
    Range("B1:B" & u1).RemoveDuplicates Columns:=1, Header:=xlNo
    'Quitar duplicados col C
    u2 = Range("C" & Rows.Count).End(xlUp).Row
    Range("C1:C" & u2).RemoveDuplicates Columns:=1, Header:=xlNo
    '
    'copiar datos de B
    u1 = Range("B" & Rows.Count).End(xlUp).Row
    Range("B1:B" & u1).Copy Range("E1")
    Range("F1:F" & u1) = "B"
    'copiar datos de C
    u2 = Range("C" & Rows.Count).End(xlUp).Row
    Range("C1:C" & u2).Copy Range("E" & u1 + 1)
    u3 = Range("E" & Rows.Count).End(xlUp).Row
    Range("F" & u1 + 1 & ":F" & u3) = "C"
    '
    'ordenar datos
    With ActiveSheet.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("E1:E" & u3), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("F1:F" & u3), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange Range("E1:F" & u3): .Header = xlGuess: .MatchCase = False
        .Orientation = xlTopToBottom: .SortMethod = xlPinYin: .Apply
    End With
    '
    'Acomodar datos
    For i = 1 To Range("E" & Rows.Count).End(xlUp).Row
        If Cells(i, "F") = "C" Then
            If Cells(i, "E") <> ant Then j = j + 1
            Cells(j, "I") = Cells(i, "E")
        Else
            j = j + 1
            Cells(j, "H") = Cells(i, "E")
        End If
        ant = Cells(i, "E")
    Next
    Application.ScreenUpdating = True
    MsgBox "Fin"
End Sub

.

'S aludos. Dante Amor. Recuerda valorar la respuesta. G racias

.

Avísame cualquier duda

.

Hola amigo! muchas gracias, funciona, pero se me olvido por completo un detalle, no sé si esto es posible, tengo números con colores azul y rojo aparte del negro, y en el resultado los colores pasan a ser todo negro, no hay alguna posibilidad de hacer que pasen con los mismos colores? perdón pero se me escapó el detalle, valoraré con excelente

por ejemplo B6 está con rojo y los primeros de arriba están azules

Prueba así:

Sub Ordenar_Numeros()
'Por.Dante Amor
    Application.ScreenUpdating = False
    j = 0
    ant = ""
    Columns("E:I").Clear
    '
    'Quitar duplicados col B
    u1 = Range("B" & Rows.Count).End(xlUp).Row
    Range("B1:B" & u1).RemoveDuplicates Columns:=1, Header:=xlNo
    'Quitar duplicados col C
    u2 = Range("C" & Rows.Count).End(xlUp).Row
    Range("C1:C" & u2).RemoveDuplicates Columns:=1, Header:=xlNo
    '
    'copiar datos de B
    u1 = Range("B" & Rows.Count).End(xlUp).Row
    Range("B1:B" & u1).Copy Range("E1")
    Range("F1:F" & u1) = "B"
    'copiar datos de C
    u2 = Range("C" & Rows.Count).End(xlUp).Row
    Range("C1:C" & u2).Copy Range("E" & u1 + 1)
    u3 = Range("E" & Rows.Count).End(xlUp).Row
    Range("F" & u1 + 1 & ":F" & u3) = "C"
    '
    'ordenar datos
    With ActiveSheet.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("E1:E" & u3), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("F1:F" & u3), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange Range("E1:F" & u3): .Header = xlGuess: .MatchCase = False
        .Orientation = xlTopToBottom: .SortMethod = xlPinYin: .Apply
    End With
    '
    'Acomodar datos
    For i = 1 To Range("E" & Rows.Count).End(xlUp).Row
        If Cells(i, "F") = "C" Then
            If Cells(i, "E") <> ant Then j = j + 1
            Cells(i, "E").Copy Cells(j, "I")
        Else
            j = j + 1
            Cells(i, "E").Copy Cells(j, "H")
        End If
        ant = Cells(i, "E")
    Next
    Application.ScreenUpdating = True
    MsgBox "Fin"
End Sub

sal u dos

¡Gracias! me ha servido de mucha ayuda, solo que en los duplicados está prevaleciendo el color negro (tiene que prevalecer el rojo o celeste), pero creo que es demasiado pedir y los estoy haciendo manualmente (son muy pocos)

DE NUEVO MUCHAS GRACIAS DANTE!