Cómo puedo fitrar un dato sin que se quite el filtro anterior en VBA

Estoy en un proyecto de recolección de datos en Visual Basic y tengo mis datos en una hoja en un rango de excel y los visualizo con un listbox el que me los filtra según el dato que yo seleccione, es decir, tengo 6 datos básicos: proveedor, producto, alto, ancho, largo y color, cuando selecciono "proveedor" me filtra mostrándome el proveedor que yo elija, pero cuando filtro "producto" me borra el filtro de proveedores mostrándome el producto con todos los que me lo proveen. Lo que necesito es que me filtre el producto que tenga el proveedor que previamente había seleccionado, conservando el proveedor y así con los demás datos hasta llegar a un solo producto con proveedor, ancho, largo, alto y color...

No sé si fui clara agradezco mucho a quien me pueda ayudar

Gracias :D

Respuesta
1

Envíame tu archivo para adaptar el código para tu listbox

Mi correo [email protected]

En el asunto del correo escribe tu nombre de usuario “Monica Tovar”

listo ya te envié el correo... podrías por favor explicarme como funciona?

muchas gracias :)

Te envío el código actualizado

Option Explicit
Dim h1, cargando
'
Private Sub cbusprv_Change()
'Por.Dante Amor
'Proveedor
    finfprv.Visible = True
    finfnueprv.Visible = False
    finfprodprv.Visible = True
    '
    cargando = True
    '
    Cprodservprv.Clear
    Cprodservprv = ""
    Cprtnpnprv.Clear
    Cprtnpnprv = ""
    Crefpnprv.Clear
    Crefpnprv = ""
    Csrefpnprv.Clear
    Csrefpnprv = ""
    Ccolorpnprv.Clear
    Ccolorpnprv = ""
    '
    If Cbusprv = "" Or Cbusprv.ListIndex = -1 Then
        cargando = False
        Exit Sub
    End If
    '
    Dim i
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        If h1.Cells(i, "F") = Cbusprv.Value Then
            Call agregar(Cprodservprv, h1.Cells(i, "Q"))
        End If
    Next
    Call Filtrar
    cargando = False
End Sub
'
Private Sub Cprodservprv_Change()
'Producto
    '
    Cprtnpnprv.Clear
    Cprtnpnprv = ""
    Crefpnprv.Clear
    Crefpnprv = ""
    Csrefpnprv.Clear
    Csrefpnprv = ""
    Ccolorpnprv.Clear
    Ccolorpnprv = ""
    '
    If Cprodservprv = "" Or Cprodservprv.ListIndex = -1 Then
        cargando = False
        Exit Sub
    End If
    If cargando Then Exit Sub
    cargando = True
    '
    Dim i
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        If h1.Cells(i, "F") = Cbusprv.Value And _
           h1.Cells(i, "Q") = Cprodservprv Then
            Call agregar(Cprtnpnprv, h1.Cells(i, "R"))
        End If
    Next
    Call Filtrar
    cargando = False
End Sub
'
Private Sub Cprtnpnprv_Change()
'Presentación
    '
    Crefpnprv.Clear
    Crefpnprv = ""
    Csrefpnprv.Clear
    Csrefpnprv = ""
    Ccolorpnprv.Clear
    Ccolorpnprv = ""
    '
    If Cprtnpnprv = "" Or Cprtnpnprv.ListIndex = -1 Then
        cargando = False
        Exit Sub
    End If
    '
    If cargando Then Exit Sub
    cargando = True
    Dim i
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        If h1.Cells(i, "F") = Cbusprv.Value And _
           h1.Cells(i, "Q") = Cprodservprv And _
           h1.Cells(i, "R") = Cprtnpnprv Then
            Call agregar(Crefpnprv, h1.Cells(i, "S"))
        End If
    Next
    Call Filtrar
    cargando = False
End Sub
Private Sub Crefpnprv_Change()
'Referencia
    '
    Csrefpnprv.Clear
    Csrefpnprv = ""
    Ccolorpnprv.Clear
    Ccolorpnprv = ""
    '
    If Crefpnprv = "" Or Crefpnprv.ListIndex = -1 Then
        cargando = False
        Exit Sub
    End If
    '
    If cargando Then Exit Sub
    cargando = True
    Dim i
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        If h1.Cells(i, "F") = Cbusprv.Value And _
           h1.Cells(i, "Q") = Cprodservprv And _
           h1.Cells(i, "R") = Cprtnpnprv And _
           h1.Cells(i, "S") = Crefpnprv Then
            Call agregar(Csrefpnprv, h1.Cells(i, "T"))
        End If
    Next
    Call Filtrar
    cargando = False
End Sub
'
Private Sub Csrefpnprv_Change()
'SubReferencia
    '
    Ccolorpnprv.Clear
    Ccolorpnprv = ""
    '
    If Csrefpnprv = "" Or Csrefpnprv.ListIndex = -1 Then
        cargando = False
        Exit Sub
    End If
    '
    If cargando Then Exit Sub
    cargando = True
    Dim i
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        If h1.Cells(i, "F") = Cbusprv.Value And _
           h1.Cells(i, "Q") = Cprodservprv And _
           h1.Cells(i, "R") = Cprtnpnprv And _
           h1.Cells(i, "S") = Crefpnprv And _
           h1.Cells(i, "T") = Csrefpnprv Then
            Call agregar(Ccolorpnprv, h1.Cells(i, "U"))
        End If
    Next
    Call Filtrar
    cargando = False
End Sub
'
Sub Filtrar()
'Por.Dante Amor
    fprodprv.Visible = True
    lprodprv.Clear
    Dim i, d1, d2, d3, d4, d5, d6
    d1 = Cbusprv
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        If Cprodservprv = "" Then d2 = h1.Cells(i, "Q") Else d2 = Cprodservprv
        If Cprtnpnprv = "" Then d3 = h1.Cells(i, "R") Else d3 = Cprtnpnprv
        If Crefpnprv = "" Then d4 = h1.Cells(i, "S") Else d4 = Crefpnprv
        If Csrefpnprv = "" Then d5 = h1.Cells(i, "T") Else d5 = Csrefpnprv
        If Ccolorpnprv = "" Then d6 = h1.Cells(i, "U") Else d6 = Ccolorpnprv
        'Si el dato de la fila coincide con textbox carga los datos al listbox
        If h1.Cells(i, "F") = d1 And h1.Cells(i, "Q") = d2 And _
           h1.Cells(i, "R") = d3 And h1.Cells(i, "S") = d4 And _
           h1.Cells(i, "T") = d5 And h1.Cells(i, "U") = d6 Then
            'Copia los datos de la celda list box
            lprodprv.AddItem
            lprodprv.List(lprodprv.ListCount - 1, 0) = h1.Cells(i, "Q")
            lprodprv.List(lprodprv.ListCount - 1, 1) = h1.Cells(i, "R")
            lprodprv.List(lprodprv.ListCount - 1, 2) = h1.Cells(i, "S")
            lprodprv.List(lprodprv.ListCount - 1, 3) = h1.Cells(i, "T")
            lprodprv.List(lprodprv.ListCount - 1, 4) = h1.Cells(i, "U")
            lprodprv.List(lprodprv.ListCount - 1, 5) = h1.Cells(i, "V")
            lprodprv.List(lprodprv.ListCount - 1, 6) = h1.Cells(i, "W")
            lprodprv.List(lprodprv.ListCount - 1, 7) = h1.Cells(i, "X")
            lprodprv.List(lprodprv.ListCount - 1, 8) = h1.Cells(i, "Y")
            lprodprv.List(lprodprv.ListCount - 1, 9) = h1.Cells(i, "AC")
        End If
    Next
End Sub
'
Private Sub bnueprv_Click()
    finfnueprv.Visible = True
    finfprv.Visible = False
End Sub
'
Private Sub twhatspvrn_Change()
    finfprodprv.Visible = True
End Sub
Private Sub UserForm_Initialize()
    tlogprv.SetFocus
    'finfprodprv.Visible = True
    '
    'Carga proveedores
    Dim i
    Set h1 = Sheets("prv")
    For i = 11 To h1.Range("F" & Rows.Count).End(xlUp).Row
        Call agregar(Cbusprv, h1.Cells(i, "F"))
    Next
    cargando = False
End Sub
'
Sub agregar(combo As ComboBox, dato As String)
    'por.DAM agrega los item únicos y en orden alfabético
    Dim i
    For i = 0 To combo.ListCount - 1
        Select Case StrComp(combo.List(i), dato, vbTextCompare)
            Case 0: Exit Sub 'ya existe en el combo y ya no lo agrega
            Case 1: combo.AddItem dato, i: Exit Sub 'Es menor, lo agrega antes del comparado
        End Select
    Next
    combo.AddItem dato 'Es mayor lo agrega al final
End Sub
'
Private Sub tlogprv_Change()
    If tlogprv = "8" Then
        fbusprv.Visible = True
        tlogprv.Visible = False
        Labelloginprv.Visible = False
    End If
End Sub

.

'S aludos. Dante Amor. Recuerda valorar la respuesta. G racias

.

Avísame cualquier duda

.

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas

Ver distintas hojas de un mismo libro en distintas pantallas

¿Pues no sé si esto se podrá hacer? Una determinada hoja de un libro se puede ver en la pantalla 2 mientras el resto de hojas, del mismo libro, las veo en la pantalla 1...¿Se puede? Si es así, ¿Cómo?
2 respuestas

Base de datos Access se bloquea al trabajar en simultaneo

En contexto tengo una base de datos donde se ingresan datos en un formulario y este a su vez tiene un subformulario. Al inicio solo era utilizada por un usuario. Pero ahora es usada por 4 usuarios más. Tengo una computadora principal donde tengo la...
3 respuestas

Error 6 en tiempo de ejecución - Desbordamiento - Campo Código. Access 2003 y VB 6.0

Estoy utilizando access 2003 y VB 6.0 quiero dar de alta un producto... Y le quiero dar la posibilidad al cliente de que pueda ingresar un Producto con un código de 30 números... En la base de datos access el formato del campo es Entero Largo...
7 respuestas

Añadir búsqueda al azar en formularios de Access

Tengo un archivo de Access que quiero modificar y actualizar para añadir nuevas preguntas a una base de datos. He visto que en el formulario hay una casilla como de verificación para seleccionar al azar las preguntas de toda la base de datos pero...
2 respuestas

Macro eliminar filas con valor

Tengo esta macro que me elimina las filas cuando el valor es #N/D, pero me ha dejado de funcionar cuando el valor es #CALC! Me podéis echar una mano. Muchas gracias. Sub Borrar_Filas() Dim ultifila As Integer 'guardo la última fila utilizada en la...
2 respuestas

Encontrar datos no coincidentes excel

Sucede que tengo que comparar dos bases de datos y encontrar los elementos no coincidentes para analizar. Se puede hacer por fórmula pero necesito algo más optimizado. El otro problema es que los datos son más de 1.48.576 capacidad de líneas de...
2 respuestas

¿Cómo resolver num a letras en excel?

En un libro excel habilitado para macros al convertir números a letras, en lugar de aparecer el resultado esperado aparece el mensaje # ¿NOMBRE?.
2 respuestas

´No sé que fórmulas usar para resolverme el problema

La imagen no me la sube y tampoco veo como se sube un fichero, os intentaré explicar lo mejor que pueda mi problema. En una hoja Excel tengo hallados los pagos por formas de pago: SUMAR.SI(D1:D16;"Efectivo";B1:B16), y...
3 respuestas

¿Cómo ajustar texto automáticamente en celdas combinadas en Excel 2019?

Solicito amablemente su valiosa ayuda para ajustar automáticamente un rango de celdas de una columna, he intentado con la opción de ajuste autamático de filas, también con al opción de ajustar texto de la pestaña inicio e incluso con la siguiente...
1 respuesta

¿Cómo usar un excel con macros desde varios ordenadores?

A tod@s! Tengo una aplicación en excel para introducir datos y visualizarlos con diferentes formularios creados. Lo que quiero hacer es: 1 Que ese libro este alojado en un sitio común y que lo puedan abrir desde varios ordenadores. 2º Que se pueda...
3 respuestas