¿Cómo abrir , copiar, pegar entre dos ficheros excel y guardar secuencialmente según las celdas de una columna?
Supongo que es una Macro.
En un fichero en una columna tengo un listado de los nombres de empleados, en otro una plantilla, necesitaría abrir la plantilla, pegar el nombre del empleado (celda por ejemplo A2 del fichero empleado) y guardar el fichero con el nombre de este empleado, a continuación celda A3 para hacer lo mismo hasta que llegue a fin de datos en columna A.
1 respuesta
Te anexo la macro. Sigue las siguientes indicaciones.
En la macro debes cambiar
"Hoja1" por el nombre de tu hoja que contiene la lista de empleados
Los empleados deberán empezar en la celda A2
"Plantilla.xlsx" por el nombre de tu libro plantilla
La hoja con la plantilla deberá estar en la primer hoja de tu libro plantilla
"B3" por la celda en donde quieres pegar el nombre del empleado
El libro "plantilla.xlsx" deberá estar abierto, es decir, deberás tener abiertos los 2 libros, el libro con los empleados y el libro "plantilla.xlsx"
Pon la siguiente macro en tu libro que contiene los empleados
Sub Copiar_Empleados_En_Plantilla()
'
' Por.Dante Amor
'
'
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Set l1 = ThisWorkbook
Set h1 = l1.Sheets("Hoja1") 'hoja con los empleados
Set l2 = Workbooks("plantilla.xlsx") 'nombre del libro plantilla
Set h2 = l2.Sheets(1)
celda = "B3" 'celda donde se pegará al empleado
'
ruta = l1.Path & "\"
For i = 2 To h1.Range("A" & Rows.Count).End(xlUp).Row
nombre = h1.Cells(i, "A").Value
h2.Copy
Set l3 = ActiveWorkbook
Set h3 = l3.Sheets(1)
h3.Range(celda) = nombre
l3.SaveAs Filename:=ruta & nombre & ".xlsx", _
FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
l3.Close
Next
MsgBox "Fin"
End SubSigue las Instrucciones para un botón y ejecutar la macro
- Abre tu libro de Excel de empleados
- Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
- En el menú elige Insertar / Módulo
- En el panel del lado derecho copia la macro
- Ahora para crear un botón, puedes hacer lo siguiente:
- Inserta una imagen en tu libro, elige del menú Insertar / Imagen / Autoformas
- Elige una imagen y con el Mouse, dentro de tu hoja, presiona click y arrastra el Mouse para hacer grande la imagen.
- Una vez que insertaste la imagen en tu hoja, dale click derecho dentro de la imagen y selecciona: Tamaño y Propiedades. En la ventana que se abre selecciona la pestaña: Propiedades. Desmarca la opción “Imprimir Objeto”. Presiona “Cerrar”
- Vuelve a presionar click derecho dentro de la imagen y ahora selecciona: Asignar macro. Selecciona: Copiar_Empleados_En_Plantilla
- Aceptar.
- Para ejecutarla dale click a la imagen.
.
'S aludos. Dante Amor. Recuerda valorar la respuesta. G racias
.
Avísame cualquier duda
.
