Quiero hacer una búsqueda en varias hojas de excel y que me devuelva las filas completas que contengan esa palabra

Te anexo la macro

Sub Buscar_En_Varias_Hojas()
'Busca una palabra en varias hojas y copia la fila completa
'Por Dante Amor
'
    Application.ScreenUpdating = False
    Set h1 = Sheets("resultado")        'hoja con resultados
    h1.Select
    '
    fila = 3
    h1.Rows(fila & ":" & Rows.Count).ClearContents
    dato = h1.Range("A1")
    If dato = "" Then
        MsgBox "Escribe un dato a buscar"
        Range("A1").Select
    End If
    '
    For Each hoja In Worksheets
        Select Case LCase(hoja.Name)
            Case LCase(h1.Name)
            Case Else
                Set h2 = Sheets(hoja.Name)
                Set r = h2.Cells
                Set b = r.Find(dato, LookAt:=xlPart)
                If Not b Is Nothing Then
                    celda = b.Address
                    Do
                        'detalle
                        h2.Rows(b.Row).Copy
                        h1.Rows(fila).PasteSpecial xlValues
                        fila = fila + 1
                        Set b = r.FindNext(b)
                    Loop While Not b Is Nothing And b.Address <> celda
                End If
        End Select
    Next
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
    MsgBox "Fin"
End Sub
'

Cambia en la macro "resultado" por el nombre de tu hoja donde quieres el resultado de la búsqueda.

Pon el dato a buscar en la hoja "resultado" en la celda A1 y ejecuta la macro

Las filas encontradas con el dato se pondrán en la hoja "resultado" a partir de la fila 3.

Sigue las Instrucciones para un botón y ejecutar la macro

1. Abre tu libro de Excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. En el menú elige Insertar / Módulo
4. En el panel del lado derecho copia la macro
5. Ahora para crear un botón, puedes hacer lo siguiente:
6. Inserta una imagen en tu libro, elige del menú Insertar / Imagen / Autoformas
7. Elige una imagen y con el Mouse, dentro de tu hoja, presiona click y arrastra el Mouse para hacer grande la imagen.
8. Una vez que insertaste la imagen en tu hoja, dale click derecho dentro de la imagen y selecciona: Tamaño y Propiedades. En la ventana que se abre selecciona la pestaña: Propiedades. Desmarca la opción “Imprimir Objeto”. Presiona “Cerrar”
9. Vuelve a presionar click derecho dentro de la imagen y ahora selecciona: Asignar macro. Selecciona: Buscar_En_Varias_Hojas
10. Aceptar.
11. Para ejecutarla dale click a la imagen.

'.[Sal u dos. Dante Amor. No olvides valorar la respuesta. 
'.[Avísame cualquier duda

.

[

'