Buscar una palabra en una fila y ver cuantas veces se repite vba excel

Puede subir una imagen de sus datos para una idea más precisa de lo que necesita.

¡Gracias! Amigo no se preocupe ya encontré mi duda yo mismo je je

Acá la respuesta

Dim BusquedaNext As Range
Dim firstAddress As String, ColumnasJuntas As String
Dim Data As String
Dim Conteo As Integer
With Range("10:10")
     Set BusquedaNext = .Find("Rocoto", LookIn:=xlValues)
     If Not BusquedaNext Is Nothing Then
        firstAddress = BusquedaNext.Address
        Do
            Conteo = Conteo + 1
            Data = Data & "," & BusquedaNext.Column
            Set BusquedaNext = .FindNext(BusquedaNext)
        If BusquedaNext Is Nothing Then
            GoTo DoneFinding
        End If
        Loop While BusquedaNext.Address <> firstAddress
      End If
DoneFinding:
End With
If Conteo > 0 Then MsgBox Right(Data, Len(Data) - 1)
ColumnasJuntas = Right(Data, Len(Data) - 1)

Si les sirve bacan

G r a c i a s por compartir el código.

Aquí otro ejemplo para considerar

Sub test2()
  Dim c As Range, Data As String
  For Each c In Rows(10).SpecialCells(xlCellTypeConstants)
    If c.Value Like "*Rocoto*" Then Data = Data & c.Column & ", "
  Next
  If Data <> "" Then MsgBox Left(Data, Len(Data) - 2)
End Sub

Gracias Dante, una consulta Como haría para poder transformar este procedimiento en una Function llamada BuscadorPlus para poder buscar no solo rocoto sino otras palabras.

Donde solo ponga BuscadorPlus("*Rocoto*", 10) algo así 10 es la fila

Pon el siguiente código en un módulo:

Function BuscadorPlus(texto As String, fila As Long) As String
  Dim c As Range, Data As String
  For Each c In Rows(fila).SpecialCells(xlCellTypeConstants)
    If LCase(c.Value) Like LCase(texto) Then Data = Data & c.Column & ", "
  Next
  If Data <> "" Then BuscadorPlus = Left(Data, Len(Data) - 2)
End Function

Y utiliza la función como una fórmula de excel:

=BuscadorPlus("*rocoto*",10)