Ir a una parte de la hoja excel según selección

Qué tienes en las celdas D5 a G5, ¿es una celda combinada? ¿Tienes el texto "Enero" o es una fecha con formato?

¡Gracias! Es una celda combinada con texto, pero me vale que me lleve lo más cerca posible.

Pon el siguiente código en los eventos de tu hoja:

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.Address(0, 0) = "B2" Then
    If Target.CountLarge > 1 Then Exit Sub
    If Target.Value = "" Then Exit Sub
    '
    Dim f As Range
    Set f = Rows(5).Find(Target.Value, , xlValues, xlWhole)
    If Not f Is Nothing Then
      f.Select
    End If
  End If
End Sub

Sigue las Instrucciones para poner la macro en los eventos de worksheet

1. Abre tu libro de excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. Del lado izquierdo dice: VBAProject, abajo dale doble click a worksheet(tu hoja)
4. En el panel del lado derecho copia la macro

Gracias de nuevo, he realizado lo que me comentas pero me funciona correctamente en los meses de enero y febrero, pero si selecciono por Ejemplo Agosto que estaría en la J112 no hace nada.

Otra opción que me valdría es poner el mes otra celda elegir el día y que me lleve a la celda que coindiera también

Pensé que los meses estaban hacia la derecha, ahora veo que están hacia abajo.

Utiliza la siguiente:

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.Address(0, 0) = "B2" Then
    If Target.CountLarge > 1 Then Exit Sub
    If Target.Value = "" Then Exit Sub
    '
    Dim f As Range
    Set f = Range("D:M").Find(Target.Value, , xlValues, xlWhole, , , False)
    If Not f Is Nothing Then
      f.Select
    End If
  End If
End Sub

Gracias ahora funciona correctamente.

¿Seria posible que realizase esto?:

En la celda D2 lo que hice fue colocar simplemente la suma de las dos celdas de la izquierda de tal manera que me formara como una especie de referencia. ¿Pues mi pregunta es es posible que si pongo un botón o simplemente después de seleccionar el mes y día me lleve a la celda de esa referencia?

Pongo como ejemplo lo que esta puesto en la imagen febrero 6 pues que me llevara a la celda H12 o mejor aun 2 celdas a la derecha es decir J12 aunque ya si me deja en la de la referencia sería perfecto.

La idea es poner los textos de las referencias en blanco o ocultos si se pudiera para que no se vean.

Gracias de antemano de nuevo

Sería en un botón.

No es necesaria la fórmula en D2. Solamente selecciona el mes en B2 y el día en B4; y cuando estés listo, presionas el botón.

Pon el siguiente código en el botón:

Sub Ir_a_Fecha()
  Dim f As Range
  '
  If [B2] <> "" And [B4] <> "" Then
    Set f = Range("D:M").Find([B2], , xlValues, xlWhole, , , False)
    If Not f Is Nothing Then
      f.Offset([B4] + 1).Select
    End If
  End If
End Sub

Funciona correctamente, ¿pero me corre en el Pc solo en Ipad y Iphone veo que no me permite el uso de Vba seria posible hacer algo tipo referencias con fórmulas?

No tengo forma de probar con Ipad o Iphone

Me refiero a usar referencias como intente antes yo en un celda poner la suma de ambas celdas de mes y día y con un buscar v o algo así que me rediriga allí