Pasar por alto una instrucción de una macro si el libro no se encuentra abierto

Como mencionas: '...si hay libros abiertos que llamaremos cembrass y putruele...' entonces queda claro que se trata de libros.

Se puede hacer la comprobación antes de llamar a cada subrutina o dentro de cada una. Te presento la 2da opción que evita repetir tantas líneas antes de cada llamada o Call.

En un módulo tendrás que declarar una variable pública (o con Dim si todas las macros estarán en el mismo módulo).

Dim erra As Byte
Sub principal()
'aquí tus instrucciones antes de los llamados
Call patruelle
'....
Call cembrass
'.....
End Sub
Sub putruele()
libro2 = "patruelle.xlsx"
Call verificaLibro(libro2)    'se verifica si está abierto
If erra = 1 Then Exit Sub
'aquí todas las instrucciones para este proceso llamado
'......
End Sub
Sub cembrass()
libro2 = "cembrass.xlsx"
Call verificaLibro(libro2)
If erra = 1 Then Exit Sub
'aquí todas las instrucciones para este proceso llamado
'.....
End Sub
Sub verificaLibro(x)
erra = 0
    On Error Resume Next
    Windows(x).Activate
    If Err.Number > 0 Then
        erra = 1
    End If
End Sub

Cualquier duda me comentás.

Revisando tu macro, entiendo que quieres verificar si los libros: "Putruele 1.xlsm", "Putruele 2.xlsm", "Putruele 3.xlsm", "Putruele 4.xlsm", están abiertos, si está abierto copia celdas, si no está abierto pase al siguiente libro.

Prueba lo siguiente, en el código puse comentarios para que veas en dónde tienes que poner tus datos:

Sub PUTRUELECOPY()
'Por Dante Amor
  Dim wb1 As Workbook
  Dim sh1 As Worksheet
  Dim libros As Variant, celdas As Variant, wb As Variant
  Dim i As Long
  '
  Application.ScreenUpdating = False
  'Nombre y hoja principales
  Set wb1 = Workbooks("Planilla General.xlsm")
  Set sh1 = wb1.Sheets("Putruele")
  '
  'Agrega los libros que quieras verificar en la siguiente línea:
  libros = Array("Putruele 1.xlsm", "Putruele 2.xlsm", "Putruele 3.xlsm", "Putruele 4.xlsm")
  'Agrega la celda destino
  celdas = Array("C3", "C11", "C19", "C27")
  '
  For i = 0 To UBound(libros)
    For Each wb In Workbooks
      If LCase(wb.Name) = LCase(libros(i)) Then
        Workbooks(libros(i)).Sheets(1).Range("J1:N6").Copy
        sh1.Range(celdas(i)).PasteSpecial xlPasteValues
        Exit For
      End If
    Next
  Next
  '
  Call TESMACOPY
  Call TDMCOPY
  '
  Application.CutCopyMode = False
  Application.ScreenUpdating = True
  MsgBox "PEDIDOS COPIADOS CORRECTAMENTE"
End Sub

[Comenta cualquier duda.