Ejecutar macros desde una lista desplegable en cada hoja

H o l a:

Si las macros son las mismas en todas las hojas, y vas a poner, por ejemplo en la celda C3 de cada hoja la validación de datos con la lista de las macros, entonces agrega el siguiente evento en ThisWirkbook

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
'Por.Dante Amor
    Select Case Sh.Name
        Case "Hoja4", "Hoja5", "Hoja6"
            If Not Intersect(Target, Range("C3")) Is Nothing Then
                Select Case Target
                    Case "Imprimir": Call MacroImprimir
                    Case "Resumen": Call MacroProceso
                    Case "Copiar": Call MacroCopiar
                End Select
            End If
    End Select
End Sub

En esta línea de la macro, pon los nombres de las hojas que tendrán la lista de validación con las macros.

Case "Hoja4", "Hoja5", "Hoja6"

Cambia "C3" por la celda donde tienes la lista de validación.

Los nombres de las macros que te puse son ejemplos, deberás reemplazarlos por los nombres de tus macros.

Instrucciones para poner la macro en los eventos ThisWorkbook

1. Abre tu libro de excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. Del lado izquierdo dice: VBAProject, abajo dale doble click a ThisWorkbook
4. Del lado derecho copia la macro

Ahora, si las macros de cada hoja son diferentes, entonces deberás agregar en los eventos de cada hoja una macro como esta:

Private Sub Worksheet_Change(ByVal Target As Range)
'Por.Dante Amor
    If Not Intersect(Target, Range("C3")) Is Nothing Then
        Select Case Target
            Case "Imprimir": Call MacroImprimir
            Case "Resumen": Call MacroProceso
            Case "Copiar": Call MacroCopiar
        End Select
    End If
End Sub

De igual manera, deberás cambiar la celda C3 por la celda en donde tienes la lista de validación y los nombres de las macros.

Sigue las Instrucciones para poner la macro en los eventos de worksheet

1. Abre tu libro de excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. Del lado izquierdo dice: VBAProject, abajo dale doble click a worksheet(tu hoja)
4. Del lado derecho copia la macro

Avísame cualquier duda que tengas.

:)
S aludos. D a n t e A m o r. Recuerda valorar la respuesta. G r a c i a s
;) 

Tengo macros comunes en todas las hojas y luego macros especificas en cada hoja. También tengo otra consulta, en el ThisWorkbook del libro tengo este código que no se como combinar con el código que tu me pones. Muchas gracias.

Disculpa no te he puesto los códigos el primero lo tengo en el worksheet de la hoja planning y el segundo necesito ponerlo en el mismo sitio pero, verdad, no se como integrar ambos códigos. Gracias. Un saludo.

Private Sub Worksheet_Change(ByVal Target As Range)
'se controla lo ingresado en filas pares en rango C6:AR30
If Intersect(Target, Range("C16:AR26,C30:AR40")) Is Nothing Then Exit Sub
If Target.Row Mod 2 <> 0 Then Exit Sub
'si se modifica un rango o si se borra contenido no se ejecuta
If Target.Count > 1 Then Exit Sub
If Target.Value = "" Then Exit Sub
'tampoco se ejecuta si 'arriba'no hay nro de día
If Target.Offset(-1, 0) = "" Then Exit Sub
Dim busco
'se pasa fecha (fila anterior) y texto según valor de target. Tabla de conversión en col M
filx = Sheets("DIASTRABAJO").Range("A" & Rows.Count).End(xlUp).Row + 1
Sheets("DIASTRABAJO").Range("A" & filx) = Target.Offset(-1, 0)
Set busco = Sheets("REFE").Range("A:A").Find(Target.Value, LookIn:=xlValues, lookat:=xlWhole)
If Not busco Is Nothing Then
    Sheets("DIASTRABAJO").Range("B" & filx) = busco.Offset(0, 1)
End If
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
'Por.Dante Amor
    If Not Intersect(Target, Range("E1")) Is Nothing Then
        Select Case Target
            Case "AGENDA": Call Módulo5.AGENDA
            Case "DIASTRABAJO": Call Módulo5.DIASTRABAJO
            Case "CALENDARIO": Call Módulo5.CALENDARIO
        End Select
    End If
End Sub

Te anexo la macro integrada

Private Sub Worksheet_Change(ByVal Target As Range)
'Por.Dante Amor
    If Target.Count > 1 Then Exit Sub
    If Target.Value = "" Then Exit Sub
    '
    If Not Intersect(Target, Range("E1")) Is Nothing Then
        Select Case Target
            Case "AGENDA": Call Módulo5.AGENDA
            Case "DIASTRABAJO": Call Módulo5.DIASTRABAJO
            Case "CALENDARIO": Call Módulo5.CALENDARIO
        End Select
        Exit Sub
    End If
    '
    'se controla lo ingresado en filas pares en rango C6:AR30
    If Intersect(Target, Range("C16:AR26,C30:AR40")) Is Nothing Then Exit Sub
    If Target.Row Mod 2 <> 0 Then Exit Sub
    'si se modifica un rango o si se borra contenido no se ejecuta
    'tampoco se ejecuta si 'arriba'no hay nro de día
    If Target.Offset(-1, 0) = "" Then Exit Sub
    Dim busco
    'se pasa fecha (fila anterior) y texto según valor de target. Tabla de conversión en col M
    filx = Sheets("DIASTRABAJO").Range("A" & Rows.Count).End(xlUp).Row + 1
    Sheets("DIASTRABAJO").Range("A" & filx) = Target.Offset(-1, 0)
    Set busco = Sheets("REFE").Range("A:A").Find(Target.Value, LookIn:=xlValues, lookat:=xlWhole)
    If Not busco Is Nothing Then
        Sheets("DIASTRABAJO").Range("B" & filx) = busco.Offset(0, 1)
    End If
End Sub

Prueba y me comentas.

:)
S aludos. D a n t e A m o r. Recuerda valorar la respuesta. G r a c i a s
;) 

Perdona que te moleste, pero el código no me funciona, no da ningún mensaje simplemente no hace nada.