Alguien que me explique código vba excel

Te comparto una explicación:

Sub test()
  Dim Ary As Variant
  Dim r As Long
  '
  'Almacena en memoria, en una matriz "Ary" el valor de los dados
 'desde la celda A2 y de la columna B hasta celda con datos de la columna A
  Ary = Range("A2:B" & Range("A" & Rows.Count).End(xlUp).Row).Value2
  'entonces el arreglo o matriz Ary tiene 2 columnas y varias filas
  '
  'crea un diccionario de datos, es como un índice de datos
 'en el índice se almacenan valores únicos (keys) y a cada valor único le puedes
 'aasignar un dato (item)
  With CreateObject("scripting.dictionary")
  '(With) Con el objeto del dictionary, cualquier método o propiedad que utilices
 'dentro del with, para hacer referencia, solamente debes poner un punto antes del
 'método o la propiedad, por ejemplo .Item, .Count, . Keys
  '
  'el siguiente ciclo For, lee los datos del arreglo
 'empezando en 1 y hasta el ultimo dato del arreglo
      For r = 1 To UBound(Ary)
         'almacena como llave en el diccionario la concatenación
         'del valor de la fila r y la columna 1 & un espacio & y el valor de la fila r y la columna 2
         .Item(Ary(r, 1) & " " & Ary(r, 2)) = Empty
         'El empty significa, como dije en las líneas arriba, en un dictionary puedes
         'almacenar la llave un dato, en este caso en cada llave no están almacendo un dato
         'solamente están almacendo un vacío
      Next r
        'en la celda C2,
 'resize(filas, columnas), signica que se va a aumentar en número de filas y de columnas
        'Resize(. Count), si se omite el segundo parámetro, entonces el valor es 0,
        ' Significa que no se está aumentando en columnas
        '.count es el número de llaves (keys) únicas en el dictionaru
        'si .count = 10, entonces el rango va desde la celda C2 y hasta la celda C11
        Range("C2").Resize(.Count).Value = Application.Transpose(.Keys)
        'las llaves (keys) y los datos (items) del dictionary,
 'están almacenados en la matriz, por decirlo de una manera,
 'de forma horizontal. Para ponerlos de forma vertical en las celdas de la C2 y
 'hacia abajo, se utiliza la instrucción Transpose
  End With
End Sub

.

Comenta si tienes alguna otra duda.