Como pasar texto a mayúsculas sin la fórmula mayusc

Puede ser con una macro:

Sub Mayusculas()
  Dim c As Range
  Dim lr As Long
  lr = Range("B:F").Find("*", , xlValues, xlPart, , xlPrevious).Row
  For Each c In Range("B1", Range("F" & lr))
    c.Value = UCase(c.Value)
  Next
End Sub

Comentas si es lo que necesitas.

¡Gracias! Tarda basteb pero cumple su cometido

Prueba la siguiente, el resultado debe ser inmediato:

Sub MayusculasConMatriz()
  Dim a As Variant
  Dim i As Long, j As Long
  a = Range("B1", Range("F" & Range("B:F").Find("*", , xlValues, xlPart, , xlPrevious).Row)).Value
  For i = 1 To UBound(a, 1)
    For j = 1 To UBound(a, 2)
      a(i, j) = UCase(a(i, j))
    Next
  Next
  Range("B1").Resize(UBound(a, 1), UBound(a, 2)).Value = a
End Sub

También prueba la siguiente y comentas:

Sub MayusculasConIf()
  With Range("B1", Range("F" & Range("B:F").Find("*", , xlValues, xlPart, , xlPrevious).Row))
    .Value = Evaluate("=IF({1},UPPER(" & .Address & "))")
  End With
End Sub

¡Gracias! La segunda probé y es muy rápida