Macro envío de correos con documentos adjuntos y rango de celdas en el cuerpo del correo
Espero se encuentren bien y me puedan apoyar con un tema porfavor.
Actualmente estoy intentando enviar rangos de celdas en el cuerpo del correo y documentos adjuntos al mismo tiempo, estoy comenzando a trabajar con macros en el correo y me ayudaron algunos códigos que vi en el foro. Tengo Excel 2016 y lo que sucede es que a veces se copia y a veces no el rango del celdas en el cuerpo del correo por lo que solo se envían los documentos adjuntos y en el cuerpo del correo no se porque aparece un -1, esto debido a que el cursor no se sitúa en el cuerpo del correo en Outlook para pegar la información, tengo la macro de la siguiente forma:
Dim Arch As String
Ruta = "D:\josroman\Desktop\Emisores\CANCELADAS"
Arch=Dir("D:\josroman\Desktop\Emisores\CANCELADAS\")
Set dam1 = CreateObject("outlook.application")
Set Dam2 = dam1.CreateItem(olMailItem)
Dam2.To = "[email protected]"
Dam2.Subject = "OPERACIONES CANCELADAS"
Dam2.Body = Range("A1:A140:G1:G140").Copy
Dam2.Display
DoEvents
Application.Wait Now + TimeValue("00:00:10")
SendKeys "^{END}", True
SendKeys "^v", True
DoEvents
Dam2.Display
DoEvents
Do While Arch <> ""
Dam2.Attachments.Add Ruta & "\" & Arch
Arch = Dir()
Loop
End Sub
1 Respuesta
Utiliza el siguiente código.
Cambia en esta línea el rango de celdas
Set rng = Sheets("Hoja4").Range("A1:F8")---
Código completo:
Sub Mail_Selection_Range_Outlook_Body()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Set rng = Nothing
On Error Resume Next
'Only the visible cells in the selection
'Set rng = Selection.SpecialCells(xlCellTypeVisible)
'You can also use a fixed range if you want
Set rng = Sheets("Hoja4").Range("A1:F8") '.SpecialCells(xlCellTypeVisible)
On Error GoTo 0
If rng Is Nothing Then
MsgBox "The selection is not a range or the sheet is protected" & _
vbNewLine & "please correct and try again.", vbOKOnly
Exit Sub
End If
With Application
.EnableEvents = False
.ScreenUpdating = False
End With
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
On Error Resume Next
With OutMail
.To = "damor"
.CC = ""
.BCC = ""
.Subject = "tst rango en html"
.HTMLBody = RangetoHTML(rng)
.Display
End With
On Error GoTo 0
With Application
.EnableEvents = True
.ScreenUpdating = True
End With
Set OutMail = Nothing
Set OutApp = Nothing
End Sub
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
"align=left x:publishsource=")
'Close TempWB
TempWB.Close savechanges:=False
'Delete the htm file we used in this function
Kill TempFile
Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function
